Excel Macros - Insert Rows above specific text to separate out by page - excel

Question

I need some help.
I have an output from a very old system which gives us trucking manifests. Think of them like shipping slips.
Each one starts with the Title " Manifest Number: ##### " Where #### is the actual number.
The catch is that when these get printed, they need to be spaced out so it's one per page. (which is never the case in the raw output.) Page one always has the first manifest (ok) but also, the second manifest. I find myself, daily, counting the spaces and inserting rows above the second manifest title until it is on the second page. Then I count the rows between the 2nd and 3rd and insert spaces above the third title until it is on page 3 and so on. When doing 18 pages, this gets tedious.
I'm looking to see if you can help me with a macro that searches out the title "MANIFEST NUMBER" then, counts the rows before the next page break (page breaks are every 47 lines) and inserts that number of rows above. Then perform that action again for the next one.
I can provide an example file if needed.
EDIT: I have solved my problem. Please see below for the code that I used.
Sub ManifestSplit()
'
' ManifestSplit Macro
Dim gap As Long
gap = 7
Dim searchText As String
searchText = "*MANIFEST NUMBER*"
Dim originalRange As Range
Set originalRange = Range("A" & (gap + 1) & ":A1000")
Dim manifestTotal As Long
manifestTotal = Application.WorksheetFunction.CountIf(originalRange, searchText)
MsgBox ("The total number of Manifests is " & manifestTotal + 1)
Dim manifestLocation As Long
Dim numberofrowstoPage
Dim newRange As Range
Dim counter As Long
If manifestTotal = 0 Then
MsgBox ("There is only one Manifest. Macro will end.")
Else
For counter = 1 To manifestTotal
Set newRange = Range("A" & (gap + 1) & ":A1000")
manifestLocation = Application.WorksheetFunction.Match(searchText, newRange, 0) + gap
' MsgBox ("The " & counter & " manifest is on line " & manifestLocation)
numberofrowstoPage = counter * 47 - manifestLocation
' MsgBox ("The Number of Rows that will be inserted is " & numberofrowstoPage)
Rows(manifestLocation & ":" & (manifestLocation + numberofrowstoPage + 1)).Insert Shift:=xlDown
gap = 47 * counter + 2
Next counter
End If
End Sub

Answer 1

No need to insert an arbitrary number of rows; just set a page beak.
Sub makeReadyForPrinting()
Dim r As Long, fr As Long
With Worksheets("sheet6")
.ResetAllPageBreaks
With .Columns(1).Cells
fr = .Find(What:="Manifest Number:*", After:=.Cells(.Cells.Count), LookAt:=xlWhole, _
SearchDirection:=xlNext, SearchOrder:=xlByRows).Row
r = .FindNext(After:=.Cells(fr)).Row
Do While fr <> r
.Parent.HPageBreaks.Add Before:=.Cells(r)
r = .FindNext(After:=.Cells(r)).Row
Loop
End With
End With
End Sub
The example in your narrative included a leading space in " Manifest Number: ##### ". I've assumed that was a typo and removed it.