Averageifs with Or - excel

Question

I have read that this may not be possible/ I am just doing it wrong so I was wondering if anyone knew a workaround (non - VBA) or could correct me? Thanks!
Col A has the price of apples and oranges
Col D has apples and Oranges
Col E has the type of fruit (Red, Yellow, Green, Purple)
I'm trying to get the average of Col A where Col D is Apples and Col E is either Red or Yellow.
I tried:
=SUM(AVERAGEIFS(A:A,D:D,"Apples",E:E,"Red"),AVERAGEIFS(A:A,D:D,"Apples",E:E,"Yellow"))/2
But it did not work - anyone have any ideas?

Answer 1

Yes you can do this:
=SUM(SUMIFS(A:A,D:D,"Apples",E:E,{"Red","Yellow"}))/SUM(COUNTIFS(D:D,"Apples",E:E,{"Red","Yellow"}))
Confirm with Enter
Edit Comparison of formulas
1) In this first screenshot all results appear similar:
2) In this second screenshot I changed cell E8 to purple. Results start to differ:
3) In this third screenshot it becomes clear there is no result using AVERAGE while there is using SUM/COUNTIFS:

Answer 2

I don't think you can add OR operations in AVERAGEIFS but you can use this (it's an array formula so you'll have to enter it with ctrl + shift + enter):
=AVERAGE(IF((D:D="Apples")*((E:E="Yellow")+ (E:E="Red")),A:A))
If you don't want to use array formula then (as an alternative to #JvdV's answer), you can use:
=SUMPRODUCT(A:A,--(D:D="Apples"), --((E:E="Red")+(E:E="Yellow")))/SUMPRODUCT(--(D:D="Apples"), --((E:E="Red")+(E:E="Yellow")))

Answer 3

Similar to the response from JvdV, you can use AVERAGEIFS directly.
=AVERAGE(AVERAGEIFS(A:A, B:B, {"a","c"}))
'for your data
=AVERAGE(AVERAGEIFS(A:A,D:D, "Apples", E:E, {"Red","Yellow"}))
Addendum:
4.00 apples Red
2.70 oranges Purple
2.13 apples Purple
2.64 apples Yellow
3.11 apples Purple
2.96 apples Purple
9.44 apples Yellow
2.07 oranges Red
3.14 oranges Purple
3.58 oranges Yellow
2.44 oranges Red
2.82 apples Red
2.86 apples Yellow
2.23 oranges Yellow
1.95 apples Red
2.37 oranges Yellow
The above sample data produces identical results for the following:
=AVERAGE(A2,A5,A8,A13,A14,A16)
=AVERAGE(AVERAGEIFS(A:A,D:D,"apples",E:E,{"red","yellow"}))
=SUM(SUMIFS(A:A, D:D, "apples", E:E, {"red","yellow"}))/SUM(COUNTIFS(D:D, "apples", E:E, {"red","yellow"}))
However when there are a different number of matches in the { OR } criteria then there are bad results.
4.00 apples Red
2.70 oranges Purple
2.13 apples Purple
2.64 apples Yellow
3.11 apples Purple
2.96 apples Purple
9.44 apples Yellow
2.07 apples Red
3.14 oranges Purple
3.58 oranges Yellow
2.44 oranges Red
2.82 apples Red
2.86 apples Yellow
2.23 oranges Yellow
1.95 apples Red
2.37 oranges Yellow