select rows that has particular number in Col D - excel

Question

In my Column D i have numbers. Normally most of the rows for Col D will have single number eg 2 or 12 or 22 and so on. However on some occasion it will have two or more numbers eg 2, 4,12. The numbers in the cell are separated by commas.
Example:
Col D
Row1 1
Row2 4
Row3 2,12
Row4 11,1
Row5 2,1
Row6 3
Row7 21
Row8 1,11,15
Row9 10,1,9
Row10 1,16
How can I select
all the rows that has in Col D the number 1
ie in the above example it would select row1,row4,row5,row8,row9 and row10
Many thks

Answer 1

This will do it:
Sub SelectRows()
Dim lastRow As Long
Dim rng As Range, rw As Range
With ThisWorkbook.Sheets("test") ' change to your specific sheetname
lastRow = .Cells.Find(What:="*", _
SearchOrder:=xlRows, _
SearchDirection:=xlPrevious, _
LookIn:=xlValues).Row
For Each rw In .Columns("D").Rows
If InStr(1, rw.Value, "1") > 0 Then
If rng Is Nothing Then
Set rng = rw
Else
Set rng = Union(rng, rw)
End If
End If
If rw.Row = lastRow Then Exit For
Next rw
End With
rng.Select
End Sub
Edit #1
This improved code has no false positives as the earlier version:
Sub SelectRows()
Dim addBool As Boolean
Dim lastRow As Long, lenTempStr As Long
Dim rng As Range, rw As Range
Dim tempStr As Variant
With ThisWorkbook.Sheets("test") ' change to your specific sheetname
lastRow = .Cells.Find(What:="*", _
SearchOrder:=xlRows, _
SearchDirection:=xlPrevious, _
LookIn:=xlValues).Row
For Each rw In .Columns("D").Rows
addBool = False
tempStr = Replace(rw.Value, Chr(32), vbNullString)
lenTempStr = Len(tempStr)
If InStr(1, tempStr, "1") > 0 Then
If lenTempStr = 1 Then
addBool = True
ElseIf InStr(1, tempStr, ",1,") > 0 Then
addBool = True
ElseIf Left(tempStr, 2) = "1," Then
addBool = True
ElseIf Right(tempStr, 2) = ",1" Then
addBool = True
End If
If addBool Then
If rng Is Nothing Then
Set rng = rw
Else
Set rng = Union(rng, rw)
End If
End If
End If
If rw.Row = lastRow Then Exit For
Next rw
End With
rng.Select
End Sub

Answer 2

Sub Maybe_A()
Dim c As Range, i As Long, a As String
a = ""
For Each c In Range("D2:D" & Cells(Rows.Count, 4).End(xlUp).Row)
For i = LBound(Split(c, ",")) To UBound(Split(c, ","))
If Trim(Split(c, ",")(i)) = "1" Then
If a = "" Then
a = c.Address(0, 0)
Else
a = a & "," & c.Address
End If
Exit For
End If
Next i
Next c
Range(a).EntireRow.Select
End Sub

Answer 3

Many thks to all of you. Much appreciated. Below is the code which I came up with your help. Not sure how good it is and if it would do, although it seems to working. I had not seen select case true being used before!
Sub FindN()
Dim rC As Range, Rng As Range
Dim sFind As String, fC1 As String, fC2 As String, fC3 As String, fC4 As String
sFind = [d3].Value 'type the numeral to find in cell D3
'find criteria - i think there are four outcomes
fC1 = sFind: fC2 = sFind & ",*": fC3 = "*," & sFind & ",*": fC4 = "*," & sFind
Rng = Range("d4:d14")
Cells.EntireRow.Hidden = False
For Each rC In Rng
Select Case True
Case rC.Value = Val(fC1) 'for numeric 1
rC.EntireRow.Hidden = False
Case rC.Value Like fC2
rC.EntireRow.Hidden = False
Case rC.Value Like fC3
rC.EntireRow.Hidden = False
Case rC.Value Like fC4
rC.EntireRow.Hidden = False
Case Else
rC.EntireRow.Hidden = True
End Select
Next
End Sub