Search and replace with wildcards in Excel VBA - excel

Question

I use comma as decimal separator, but sometimes I receive files where values are below a set limit, and then the file uses point as "<2.5". Sometimes there is one digit before the decimal separator, and sometimes there are two digits.
I need to be able to replace the point with a comma in cells with begin with the "less than" symbol, but retain the actual numbers, so that "<2.5" is replaced with "<2,5" and "<10.0" is replaced with "<10,0". This needs to be done in Excel VBA.
I can't do a general search for "." and replace with ",", since there are places where I need to keep the point as it is.
Anyone have an idea of how to achieve this?

Answer 1

Approach via Replace function
You could read in data to a datafield array, replace the mentioned "<" data via Replace function and write them back in one statement by the following code. - Of course it's possible to use RegEx, too as mentioned in above comment.
Notes
a) I assume you are using data in column A:A via Set rng = ws.Range("A1:A" & n); this can easily changed to any other range.
b) Assigning values to a variant datafield array automatically creates a one based 2-dim array, which you address in case of one column only e.g. via v(1,1), v(2,1), v(3,1) etc. to v(n,1).
Example Code
Option Explicit
Sub replaceLowerThan()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("MySheet") ' << Change to your sheet name
Dim n As Long, i As Long
Dim rng As Range
Dim v
' get last row number and define data range
n = ws.Range("A" & ws.Rows.Count).End(xlUp).Row
Set rng = ws.Range("A1:A" & n)
' write data to 1-based 2-dim datafield array
v = rng.Value2
' replace "<..." values
For i = 1 To n
If Not IsError(v(i, 1)) Then ' omit cells with errors like #DIV/0!
If v(i, 1) Like "<*" Then v(i, 1) = Replace(v(i, 1), ".", ",")
End If
Next i
' write values back
rng.Value2 = v
End Sub

Answer 2

This worked:
Dim strPattern As String: strPattern = "(<[0-9]+)[\.]"
Dim strReplace As String: strReplace = "$1,"
Dim myreplace As Long
Dim strInput As String
Dim Myrange As Range
Set RegEx = CreateObject("VBScript.RegExp")
Set Myrange = ActiveSheet.UsedRange
For Each cell In Myrange
If strPattern <> "" Then
strInput = cell.Value
With RegEx
.Global = True
.MultiLine = True
.IgnoreCase = False
.Pattern = strPattern
End With
If RegEx.Test(strInput) Then
cell.Value = (RegEx.Replace(strInput, strReplace))
End If
End If
Next