I'm an intermediate Excel user, so you can assume I know the basics. I've got a table for a game that contains the level, and the experience required to get to that level from level 1. Basically I have the below:
Col A Col B
Level Experience Needed
1. 0
2. 10
3. 58
4. 160
5. 329
...
79. 551,002
80. 568,832
I was trying to make a simple UI in the cells themselves where you can just input your current level, input the level you want to get to, and have a formula calculate (essentially just the exp. required for the level you want minus the experience required to get to the current level)
I've searched and cannot find anything that will help me here. I'm sure there's a way (and probably a stupidly easy one) to do what I'm trying to do, but I am at a loss.
What I pictured in my head was something that just took the number input and put that to the cell reference (eg. input 44 and it would then reference B44)
I was hoping for something in-cell, but if it needs to be code in VisualBasic I can get over it (just not really comfortable programming!)
Thanks in advance for the help!
Edit: Can either be in Excel or Google Sheets, not sure if either is easier/harder than the other.
I put current level in cell E1 and desired level in E2 The following formula will pull the values out of the Experience Needed column and subtract them. Is that what you are looking for?
=INDIRECT("B"&E2+1)-INDIRECT("B"&E1+1)
Related
I'm all new to VBA and have mostly been trying to modify code after recording macros, so it's all pretty basic and the approach might not be as elegant as some of the stuff I've seen on here. So here we go.
I have coded (by brute force) my data to be arranged like a CAD design tree view with parent products/assemblies and constituent sub-assemblies/parts.
Column E contains Level 0 top assembly Part Number
Column F contains Level 1 items Part Number
... etc all the way to ...
Column M containing Level 8 items Part Number
As an example, cell G112 contains ASSY1; cells H113 to H134 contain its constituent items.
I would like to display in a new column (i.e. Column O) the value of cell G112 (ASSY1) for each of its constituents. So O113 to O134 would show the value of G112. That would need to be applied to every single level of the assembly.
I'm not sure I'm making much sense do please have a look at the picture linked below, it speaks a thousand words. I've highlighted and colour-coded the result I would like in column O.
ADDENDUM - To clarify things:
I don't know how else to explain my request but to post a simplified version of my original picture.
SIMPLIFIED EXCEL TABLE
.CSV available here WeTransfer
A very useful tool to retrieve VBA code for determined action is the macro recorder, in the ribbon, Developer -> RecordMacro, perform you action and stop recording and then you can check the code generated for the actions you recorded. Its not the cleanest code but you can find there the lines of code for the specific actions you want. Once you step into a one concrete problem with the code you tried, you can then ask for help regarding something more concrete, more than expecting that someone will code that for you.
Anyhow if you want someone to try to solve your problem, you need to post the table with the accessible data instead of the image, for the person whoever tries to approach your problem to have the data available.
Hope that helps
Here's the answer I got from somewhere else if anyone is interested:
Formula in Cell O3:
=IF(C3=0,"N/A , ALREADY TOP LEVEL",INDEX(D$2:D2,AGGREGATE(14,6,(ROW(D$2:D2)-ROW(D$2)+1)/(C$2:C2=C3-1),1)))
Copy/Paste down in every cell in column O
I'm trying to design a second page that shows % results of my data on page 1.
For example, Column F & G allow manual entry of numbers 1-4 which are based off data the user types in at another location.
This is being used for trade tracking in investments so there will be quite a few numbers but the end result will be a row will show a specific stock, it's subsequent data, whether it made or lost money, etc.
What I want to do in page 2 is using the numbers 1-4 which were typed in at columns F & G, translate that into an edge on page 2.
For example, if there were 50 columns of data typed out for trades executed, I could take the number of winning trades of a certain setup (say number 3) and divide that by the total trades of 50 to come out with a win % for that setup.
However, I have no clue to how to translate that forumla into a filter formula so that on page 2 I could see that of the numbers 1-4 (4 different setups) I could easily see the highest and lowest win % to determine the best setup to use.
I'm not the best in excel but I understand enough to code most of that, I simply have no idea how to take that end formula and add a filter to it so that it only uses partial results. I've got 4 other formulas I want to use on page 2 as well to help build something that could really benefit myself, but if someone could just show me how to filter data into a formula, I think I could take it form there.
Thanks for the help
Ben
You can also do something like this with array formulas
=MAX(IF(Sheet1!$F$2:$F$50=$A2,$E$2:$E$50))
(Press Ctrl+Shift+Enter [CSE], instead of just Enter when entering Array Formulas)
Also, take a look a the SUMPRODUCT function. It comes in very handy for filtering data. Here are some helpful links...
https://www.get-digital-help.com/2017/12/07/sumproduct-multiple-criteria/
https://www.get-digital-help.com/2017/12/08/sumproduct-and-if-function/
https://www.get-digital-help.com/2010/09/01/extract-a-unique-distinct-list-by-matching-items-that-meet-a-criterion-in-excel/
Ive got an issue register spreadsheet, which is like a punch card system for when a document revision was published.
In the columns B-M i have the revision numbers for each document and in column A i want to have a record of the latest revision so it can be refered to quickly. At the moment i manage this by hand but have been trying to find a formal to manage column A for me.
In pseudo code it should be :
A2 = the last published number in B2-M2 But ive been struggling to think of the right way to write this with a native spreadsheet function without using VBA / google spreadsheet JS script.
Ive created a dummy spreadsheet here to illustrate the problem : https://docs.google.com/spreadsheets/d/1J6ETdlR2GEg-OeU4hojUe8bmH42zwP1GsQLyinDzHSg/edit#gid=0
Any help would be much apprecaited.
Please try:
=INDEX(B2:M2,MATCH(99,B2:M2))
copied down to suit (assumes rev numbers will not exceed 98 - if text format replace 99 with "zzz").
I've been looking for hours on this I can't really come up with anything that's going to work. Hopefully I can gain some insight here.
Here is the problem guys. I'm trying to come up with a better solution for sorting inventory. The particular items have bar codes on them so I figured it would be easy to hop in excel and plug away. The problem that I'm running into is that I can't really figure out how to assign a "lot" or "location" number for a specific item and be able to reuse that if it comes up later. For example:
Model Input Location
st1000dm003 1
ST336706LC 2
st1000dm003 1
st1000dm004 3
ST336705LC 4
st1000dm003 1
Preferably, the numbering would start at 1 and move up. The group of items in column A might not always be the same, so a table with the model number and the location will not work. It has to be able to tell if it's seen that before and what number was assigned or assign a new one if it has not been seen. The other issue that I'd most likely run into, is that I'd like to be able to run this on Office Mobile for Office 365 on Android at some point. Any help is really appreciated!
Assuming row 1 is a header row and actual data starts in row 2, put this in cell B2 and copy down:
=IF(A2="","",IF(COUNTIF(A$1:A1,A2)>0,VLOOKUP(A2,A$1:B1,2,FALSE),MAX(B$1:B1)+1))
I have a worksheet, in where I need a search that does more than one query. The problem I am running into is this:
On the workbook there are two tabs, the first is Jobs, the second is OOR. In OOR there are multiple columns empty, Order Qty., Orig Promise Date, and Shop Order.
Now I know there are duplicates, and this is fine, what I am looking at now is to use Column B in OOR is a refrence. So in this case use B3 as the refrence point. which is a partial number of 48900421 Rev 2. What I want to do is this, use two refrence points.
I want to look up B3 in OOR, and use two points of refrence to gurantee the correct job is refrenced. Those two columns to refrence is in Jobs. The first is Column B which will always equal Dakota Systems, Inc., and the other will reference Column C, but this is where I don't know what to do here, I since C3 in OOR only shows 48900421, it will never find 48900421 Rev 2I thought about using something like this:
=IFERROR(INDEX(Jobs!$E:$E,MATCH(1,INDEX((OOR!$C:$C=$B3)*(Jobs!$C:$C="Dakota Systems, Inc."),1),0)),"")
But for some reason I am getting a blank when I don't think I should be. I'm loosing my sanity this late in the week, can someone help?
https://dl.dropbox.com/u/3327208/Excel/twosearches.xlsx
You don't seem to be referencing the right columns....and also you need a zero in the second INDEX function, not a 1
Try this version in in OOR!I3 copied down, using ISNUMBER(FIND to find your part number within other text:
=IFERROR(INDEX(Jobs!E$3:E$1000,MATCH(1,INDEX(ISNUMBER(FIND(B3,Jobs!C$3:C$1000))*(Jobs!B$3:B$1000="Dakota Systems, Inc."),0),0)),"")
format in required date format
Revised re comment below:
=IFERROR(INDEX(Jobs!E$3:E$1000,MATCH(1,INDEX(ISNUMBER(FIND(B3,Jobs!C$3:C$1000))*(Jobs!B$3:B$1000="Dakota Systems, Inc.")*(Jobs!A$3:A$1000=M3),0),0)),"")