Find Multiple Strings - Exact Match - string

Question

Having little trouble here in which I'm looping through a big document and highlighting strings. Where I'm having trouble is two fold, eg.
Search Criteria "aaa" in cell "Baaa", this would get highlighted as a hit, which on some level makes sense, but I was hoping only to return highlight if exact match in string and length. Also I'm curious if there is an easy way to compress the following:
Sub Sample()
Dim MyAr(1 To 1092) As String
Dim ws As Worksheet
Dim aCell As Range, bCell As Range
Dim i As Long
Set ws = ThisWorkbook.Sheets("Sheet1")
MyAr(1) = "R833"
MyAr(2) = "R853"
MyAr(3) = "R873"
With ws
'~~> Loop through the array
For i = LBound(MyAr) To UBound(MyAr)
Set aCell = .Columns(23).Find(What:=MyAr(i), LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If Not aCell Is Nothing Then
Set bCell = aCell
aCell.Interior.ColorIndex = 3
Do
Set aCell = .Columns(23).FindNext(After:=aCell)
If Not aCell Is Nothing Then
If aCell.Address = bCell.Address Then Exit Do
aCell.Interior.ColorIndex = 3
Else
Exit Do
End If
Loop
End If
Next
End With
With ws
'~~> Loop through the array
For i = LBound(MyAr) To UBound(MyAr)
Set aCell = .Columns(24).Find(What:=MyAr(i), LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If Not aCell Is Nothing Then
Set bCell = aCell
aCell.Interior.ColorIndex = 3
Do
Set aCell = .Columns(24).FindNext(After:=aCell)
If Not aCell Is Nothing Then
If aCell.Address = bCell.Address Then Exit Do
aCell.Interior.ColorIndex = 3
Else
Exit Do
End If
Loop
End If
Next
End With

Answer 1

You have this LookAt:=xlPart in your FIND statement.
Change this to LookAt:=xlWhole to only search for exact matches.
Note: This means the whole cell must match, not just that one word amongst many in the cell.
To find an exact match on a word amongst many use xlPart but add a space at the start and end of your search term - search for " aaa " rather than "aaa".
Edit: It looks like your code could be shortened, unfortunately I haven't got the time to look at it at the moment.

Answer 2

Building on #Darren Bartrup-Cook's comments, you can shorten it thus, though I doubt you need to search the full column?
Sub Sample()
Dim MyAr(1 To 1092) As String
Dim ws As Worksheet
Dim aCell As Range, bCell As Range
Dim i As Long
Set ws = ThisWorkbook.Sheets("Sheet1")
MyAr(1) = "R833"
MyAr(2) = "R853"
MyAr(3) = "R873"
With ws
'~~> Loop through the array
For i = LBound(MyAr) To UBound(MyAr)
Set aCell = .Range("W:X").Find(What:=MyAr(i), LookIn:=xlValues, _
LookAt:=xlWhole, MatchCase:=False, SearchFormat:=False)
If Not aCell Is Nothing Then
Set bCell = aCell
Do
aCell.Interior.ColorIndex = 3
Set aCell = .Range("W:X").FindNext(After:=aCell)
Loop While aCell.Address <> bCell.Address
End If
Next
End With
End Sub