Gnuplot pm3d map: different x2tics, y2tics - gnuplot

Question

I can plot a "ploe figure" with:
degtorad(x)=x/180*pi
radtodeg(x)=x/pi*180
set pm3d map
set pm3d interpolate 0,0
set logscale zcb
set palette model RGB rgbformulae 33,13,10
set size ratio 1
set xtics("{/Symbol b}=180{/Symbol \260}" 0)
set ytics("0" -90, "10" -80, "20" -70, "30" -60, "40" -50, "50" -40, "60" -30, "70" -20, "80" -10, "90" 0, "80" 10, "70" 20, "60" 30, "50" 40, "40" 50, "30" 60, "20" 70, "10" 80, "0" 90)
splot[-90:90][-90:90] 'TSC3.txt' u (radtodeg(cos(degtorad($1+90))*degtorad(90-$2))):(radtodeg(degtorad(90-$2)*sin(degtorad($1+90)))):3 notitle
where column 1 contains "beta", column 2 is "alpha" but it doesn't matter.
The question is
how to remove the right ticmarks (unset y2tics doesn't work)?
how to set "beta=0°" on the upper side (set x2tics("{/Symbol b}=0{/Symbol \260}" 0) doesn't work)?

Answer 1

The unlabelled tics on the right and top border have nothing to do with the x2- and y2-axis. They are the mirrored tics of the x- and y-axis. To switch the right tics off, use set ytics ... nomirror.
If I remember correctly, in earlier versions splot didn't work at all with x2 and y2 axes. At least with 5.2 you can link the x2 axis to have the same range as the x axis with set link x2 and then you can place tics on the x2 axis:
degtorad(x)=x/180*pi
radtodeg(x)=x/pi*180
set pm3d map
set pm3d interpolate 0,0
set logscale zcb
set palette model RGB rgbformulae 33,13,10
set size ratio 1
set link x2
set x2tics ("{/Symbol b}=180{/Symbol \260}" 0)
set ytics nomirror ("0" -90, "10" -80, "20" -70, "30" -60, "40" -50, "50" -40, "60" -30, "70" -20, "80" -10, "90" 0, "80" 10, "70" 20, "60" 30, "50" 40, "40" 50, "30" 60, "20" 70, "10" 80, "0" 90)
splot[-90:90][-90:90] 'TSC3.txt' u (radtodeg(cos(degtorad($1+90))*degtorad(90-$2))):(radtodeg(degtorad(90-$2)*sin(degtorad($1+90)))):3 notitle