Build VB.NET string from array of Integers - string

Question

I need to construct a string from Unicode values found in a .csv file. I have used Python to extract the integer values and I need to rebuild the string in VB.NET to check for the presence of the string with a file parser.
I've tried using both the Chr and ChrW functions but both give me errors when I hit the 8315 value.
Public Function FromAsciiArray(AsciiArray As Integer()) As String
Dim strOut As String = ""
For Each asciiValue In AsciiArray
strOut += ChrW(asciiValue)
Next
Return strOut
End Function
Dim strVECTOR = FromAsciiArray(
New Integer() {86, 69, 67, 84, 79, 82, 32, 40, 109, 109, 47, 115, 8315, 185, 41}
)
Anyone know how to do this?

Answer 1

This works:
Dim arr = New Integer() {86, 69, 67, 84, 79, 82, 32, 40, 109, 109, 47, 115, 8315, 185, 41}
Dim str = String.Concat(arr.Select(Function(n) Convert.ToChar(n)))
Console.WriteLine(str)

Answer 2

Public Function FromIntegers(CharacterValues As IEnumerable(Of Integer)) As String
Return New String(CharacterValues.Select(Function(c) Convert.ToChar(c)).ToArray())
End Function
This will work with Arrays, Lists, and other integer sequences (thus removing "Array" from the name, and fixing the "ASCII" while we're at it). You can call it just like you did in the question:
Dim VECTOR As String = FromIntegers(
New Integer() {86, 69, 67, 84, 79, 82, 32, 40, 109, 109, 47, 115, 8315, 185, 41}
)
... where I made the slight adjustment that modern code tends to declare the type of the variable with the definition instead of with a name prefix.
If you really want to have fun, you can also do this:
Public Function FromIntegers(ParamArray CharacterValues() As Integer) As String
Return New String(CharacterValues.Select(Function(c) Convert.ToChar(c)).ToArray())
End Function
which will let you call the function like just like you did in the question:
Dim VECTOR As String = FromIntegers(
New Integer() {86, 69, 67, 84, 79, 82, 32, 40, 109, 109, 47, 115, 8315, 185, 41}
)
And also call it like this:
Dim VECTOR As String = FromIntegers(86, 69, 67, 84, 79, 82, 32, 40, 109, 109, 47, 115, 8315, 185, 41)
Finally, if you're sure of the character encoding and depending on how the Python side handles things or how you parse the csv data, we might be able to do a little better still via the System.Text.Encoding family of classes.