code does only run correctly in break mode - excel

Question

After hours and days of searching the web in order to find a hint how to fix a bug in my code, I am completely clueless about what might be going on, and am hoping to get some advise from this community.
The code is somewhat complicated, therefore I will not add any snippets, but rather try to explain as simple as I can get it.
I have created a tool (excel macro) that does a lot of analyses on certain data, collected at customer sites using our software (mostly multiple users)
This tool runs well since years, including e.g. filtering to only take into account users that match certain criteria
I want to expand that tool in a way so that it automatically runs multiple times - once for each user.
The way how this works is:
The tool processes data from the first user, and saves the result as a new excel spreadsheet (in which the code continues to run).
the tool processes data from the next user, and again saves the result as a new spreadsheet, and so on.
In the second run the weird behaviour happens: If run in regular mode, the code breaks due to an error; if the code is interrupted by a 'stop' right before the line producing the error and code completion is continued, everything works perfectly fine.
The problem occurs at assignment of a table as range:
Dim rr As Range
Set rr = Workbooks(actWBK).Worksheets(shtName).Range(tableName & "[[#All],[" & header & "]]")
From the second run onwards, the line starting with Set... produces an error (application-defined or object-defined error).
The fact that this assignment works perfectly in the first run made me believe that there is some kind of unspecified assignment to a workbook or the like, but I tested all options and could rule that out;
The really staggering thing is that, as mentioned, when I add a "stop" before, the code works perfectly fine.
I am really out of any ideas, so every answer is more than welcome!
Thank you in advance,
Alexander
I will try to add some code.
The problem occurs in the module sortTable (relevant part after "code here", I always use this kind of "template" to set some standard things):
Sub sortTable(sheetName As String, tableName As String, header As String, dir As XlSortOrder)
' here only logging and error handling settings
'---------------------------------------------------------------------------------------
' code here
'---------------------------------------------------------------------------------------
' deal with #-sign in header
Dim headerParts() As String
headerParts = Split(header, "#")
Dim cleanHeader As String
If UBound(headerParts) = -1 Then
successcode = 2
GoTo errorHandler
ElseIf UBound(headerParts) = 0 Then
cleanHeader = header
Else
cleanHeader = headerParts(0)
Dim i As Integer
For i = 1 To UBound(headerParts)
cleanHeader = cleanHeader & "'#" & headerParts(i)
Next i
End If
' sorting
Dim actWBK As String
actWBK = ActiveWorkbook.name
Dim rr As Range
Set rr = Workbooks(actWBK).Worksheets(sheetName).Range(tableName & "[[#All],[" & cleanHeader & "]]")
ActiveWorkbook.Worksheets(sheetName).ListObjects(tableName).Sort.SortFields _
.Clear
ActiveWorkbook.Worksheets(sheetName).ListObjects(tableName).Sort.SortFields _
.Add key:=Range(tableName & "[[#All],[" & cleanHeader & "]]"), SortOn:=xlSortOnValues, Order _
:=dir, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets(sheetName).ListObjects(tableName).Sort
.header = xlYes
.MatchCase = True
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
'---------------------------------------------------------------------------------------
' sub cleanup on exit; don't make changes below this line
'---------------------------------------------------------------------------------------
' here only logging and error handling
End Sub
The procedure is called from a different module called QuickSort which takes as argument an array:
Public Sub QuickSort(vArray As Variant)
' here only logging and error handling
Dim wsName As String
wsName = "tempSort"
Application.DisplayAlerts = False
On Error Resume Next
Sheets(wsName).Delete
On Error GoTo errorHandler
Application.DisplayAlerts = True
Worksheets.Add After:=Sheets(Sheets.count)
ActiveSheet.name = wsName
Cells(1, 1) = "Header"
Dim rr As Range
Set rr = Range(Cells(2, 1), Cells(UBound(vArray) + 2 - LBound(vArray), 1))
Set rr = rr.Resize(UBound(vArray) + 1 - LBound(vArray), 1)
rr.value = myTransposeArray(vArray)
Set rr = Nothing
ActiveSheet.ListObjects.Add( _
xlSrcRange, _
Range(Cells(1, 1), Cells(UBound(vArray) + 2 - LBound(vArray), 1)), _
, xlYes).name = "tempSortTable"
sortTable sheetName:=wsName, tableName:="tempSortTable", header:="Header", dir:=xlAscending
' more code hereafter

Answer 1

Try changing this
Dim actWBK As String
actWBK = ActiveWorkbook.name
Dim rr As Range
Set rr = Workbooks(actWBK).Worksheets(sheetName).Range(tableName & "[[#All],[" & cleanHeader & "]]")
To
Dim actWbk as workbook
Set actwbk = activeworkbook
dim ws as worksheet
set ws = actwbk.worksheets(sheetname)
dim s as string
s = tableName & "[[#All],[" & cleanHeader & "]]"
Dim rr as range
Set rr = ws.range(s)
Then when it breaks you can inspect each in turn to see if they point to what you think they should

Answer 2

A collegue of mine found a workaround to overcome the problem (all credits onto you, Thomas!):
instead of referencing the range as
Set rr = Workbooks(actWBK).Worksheets(sheetName).Range(tableName & "[[#All],[" & cleanHeader & "]]")
I changed the code to
Set rr = Workbooks(actWBK).Worksheets(sheetName).ListObjects(tableName).ListColumns(cleanHeader).Range
By that, everything works perfectly fine, no matter if in the first run or in subsequent runs.
There is also a suspicion what might cause the problem (which clearly is not resolved itself, this solution is just a workaround!), and it has to do with something going on during saving the workbook using SaveAs.
I am not clear at all what could be this reason, but for those who face a similar problem, I'd like to explain what I did in my code:
By opening a file containing the tool
AnalysisTool.xlsm
the macro starts running. In order to get data, the code opens an xml file as excel table; this table temporarily is called something like
Book1.xlsx
The code copies the data from Book1 to AnalysisTool; in order to remain the tool unchanged, the file is saved as something like
AnalysisResult_20180222_01.xlsm <- this is the file in which code is executed!
Book1 is closed without saving.
When the analysis is finished, the workbook is saved without close.
Upon re-run,
All result tabs in AnalysisResult_20180222_01.xlsm are deleted, a new xml data file is opened, data is copied, and the code-bearing file is saved as
AnalysisResult_20180222_02.xlsm <- this is the file in which code now is executed!
etc.
As I said, I am not sure what goes wrong, but by changing this one line as described makes everything work perfectly fine.
Hope this might be helpful to anybody!