Workbooks.Open failing in specific circumstances - excel

Question

So I have a a function in my project that's is built to look for a workbook, check if it's open, then open that workbook if it's closed.
Public Function CheckOpen(wbName As String)
Dim wb As Workbook
Dim Ret_type As Integer
Dim strMsg As String
Dim strTitle As String
Dim tempstr As String
Dim x As Integer, y As Integer
On Error Resume Next
Set wb = Application.Workbooks(wbName)
On Error GoTo 0
strTitle = "Workbook Not Open"
strMsg = "Workbook " + wbName + " isn't open, press 'Retry' to fix."
If wb Is Nothing Then
'The workbook isn't open
Ret_type = MsgBox(strMsg, vbRetryCancel + vbQuestion, strTitle)
Select Case Ret_type
Case 4
'Retry Case
On Error Resume Next
For x = 1 To 2
For y = 1 To 2
Workbooks.Open (FindFilePath(x) + FileEndingManager(wbName, y))
Debug.Print (FindFilePath(x) + FileEndingManager(wbName, y))
Next y
Next x
Case 2
'Cancel Case
MsgBox "You clicked 'CANCEL' button."
End Select
End If
End Sub
TO CLARIFY: This function works when called directly. As in:
Sub TestCheck()
Call CheckOpen("WorkbookName")
End Sub
That's fine. Everything works. However, when I Call this function from a function entered in the actual spreadsheet the MsgBox appears, but it never opens the required workbook.
I don't understand what is going on.

Answer 1

Using Functions (UDFs)
As mentioned in comments #jkpieterse
A function called from a cell cannot do things like opening workbooks
Functions are able to be called from a cell just like Excel's built in functions and they always return something to the cell (even if it's only an error).
For a function to return something, other than an error, it must have a line like
FunctionName = *a value that complies with the function declaration*
Functions are available in auto-complete in Excel, even if they return a #VALUE! error which will occur if you don't set a return as described above. That's probably going to frustrate users!
Any other errors in a UDF will also cause a #VALUE! error and the only way to find them is by stepping through the function using F8. They don't show up at compile time!
So there are at least 2 reasons not to use a function where a sub would suffice.
If you want to change any book or sheet objects then declare a Sub procedure.
Use UDFs sparingly!
To answer your question:
I've tried to refactor your code into a worksheet callable function that will work with a Sub procedure while still using your variables.
I don't know what FindFilePath(x) or FileEndingManager(wbName, Y) do so assume they do work.
Public Function CheckOpen(wbName As String) As Boolean
Dim wb As Workbook
On Error Resume Next
Set wb = Application.Workbooks(wbName)
On Error GoTo 0
If Not wb Is Nothing Then
CheckOpen = True 'the essence of a "Function" - it returns a value!
End If
End Function
Or you could use this alternate function that doesn't require On Error Resume Next
Public Function CheckOpen1(wbName As String) As Boolean
Dim wb As Workbook
For Each wb In Workbooks 'in all the workbooks you have open
If wb.Name = wbName Then
CheckOpen = True 'if not, CheckOpen will remain FALSE
End If
Next
End Function
Then your Sub procedure looks like:
FileEndingManager(wbName, y)
Sub TestCheck()
Dim Ret_type As Integer
Dim strMsg As String
Dim strTitle As String
Dim tempstr As String
Dim x As Integer, y As Integer
If Not CheckOpen("WorkbookName") Then
strTitle = "Workbook Not Open"
strMsg = "WorkbookName isn't open, press 'Retry' to fix."
Ret_type = MsgBox(strMsg, vbRetryCancel + vbQuestion, strTitle)
Select Case Ret_type
Case 4
'Retry Case
On Error Resume Next
For x = 1 To 2
For y = 1 To 2
Workbooks.Open (FindFilePath(x) + FileEndingManager(wbName, y))
Debug.Print (FindFilePath(x) + FileEndingManager(wbName, y))
Next y
Next x
On Error GoTo 0 'end the Resume Next ASAP
'Check if the x, y loop has opened WorkbookName
If Not CheckOpen("WorkbookName") Then 'probably can't be opened
strMsg = "WorkbookName can't be opened! Clicking OK will exit sub."
MsgBox strMsg, vbCritical, strTitle
Exit Sub
End If
Case 2 'Tell user something they know! Not necessary
'Cancel Case
MsgBox "You clicked 'CANCEL' button." 'delete this line and just exit
Exit Sub
End Select
End If
'Haven't exited yet so safe to proceed
'...do things with WorkbookName
End Sub