I have raw data from an Excel Query that gives me details for Account Numbers(Field 2). I also have a list of Account Numbers that I want to EXCLUDE from the raw data.
Initially, I thought I could exclude them in SQL with the NOT IN condition. But I was then told that there are about 20,000 Accounts to Exclude.
So, I thought, I could export the raw data to Excel in one Worksheet and Add the Account Numbers to exclude in another worksheet and then have Excel check for those Account Numbers and give a Comment.
Worksheet 1 (Raw Data):
---------------------------------
|Field 1|Field 2|Field 3|Field 4|
---------------------------------
| 1234| A1234B| XYZ| 258.00|
---------------------------------
| 2678| B1234C| ABC| 457.25|
---------------------------------
| 5465| C1234D| DEF| 652.47|
---------------------------------
| 4587| D1234E| GHI| 458.36|
---------------------------------
| 3589| E1234F| JKL| 685.47|
---------------------------------
Worksheet 2 (Accounts to Exclude):
---------
|Field 2|
---------
| A1234B|
---------
| J1234L|
---------
| K1234Z|
---------
| D1234E|
---------
| L1234M|
---------
Intended Result:
------------------------------------------
|Field 1|Field 2|Field 3|Field 4|Result |
------------------------------------------
| 1234| A1234B| XYZ| 258.00|Excluded|
------------------------------------------
| 2678| B1234C| ABC| 457.25| |
------------------------------------------
| 5465| C1234D| DEF| 652.47| |
------------------------------------------
| 4587| D1234E| GHI| 458.36|Excluded|
------------------------------------------
| 3589| E1234F| JKL| 685.47| |
------------------------------------------
Initially, I started by sorting the Account Numbers on both worksheets and then ran the formula:
=IFERROR(VLOOKUP(B2,ExcludedAccounts,2,FALSE), "Excluded")
But then I realised, I am only looking for exact match for each cell. That won't be right.
Question:
What is the Formula to check two columns from different worksheets for similarities across the whole column?
Once I have the flag "Excluded" in another column then I can highlight cell with Conditional Formatting and then segregate those accounts.
Not enough rep to post a comment. The OPs formula is fine, if the "ExcludedRange" covers two columns (as he is returning what is in the second column) with the second column containing only blank spaces.
I'm not sure though what is meant by the below - could you please explain what the similarities are...
...different worksheets for similarities across the whole column
This is another way of doing it with a single column for the excludedrange
=IF(ISERROR(VLOOKUP(A2,ExcludedAccounts,1,0)),"Excluded","")
I think the formula you're actually looking for is
=IF(ISNUMBER(MATCH(B2,ExcludedAccounts,0)),"Excluded","")
When I used your formula, all I received were "Excluded" answers for everything because it was returning an error (this was possibly caused by missing information in your question, but I don't know). EDIT: As stated in the other answer that was submitted, yes, the original formula was looking to return a value from a second column, which would mean that ExcludedAccounts covers a minimum of two columns, not the assumed one.
There are several ways you can handle your request. However, what my above formula does is look for an exact match of the value in B2 against those values in the ExcludedAccounts named range (which I assumed is Sheet2!A2:A6). If MATCH finds one, a number will be returned (this number represents the row within ExcludedAccounts where the value from B2 was found). By wrapping this in the ISNUMBER function and placing it inside an IF statement, we're asking Excel to give us the result of "Excluded" if the excluded account is found on the list, and a result of "" if it isn't on the ExcludedAccounts list.
Related
Good Afternoon all,
I've had a search but can't find the answer - please direct me if there is one!
I'm looking to make my spreadsheet have better readability to the user. It requires a lot of manual work outside of the sheet, so the less time strain the spreadsheet is, the better.
I know to to use =mod() in Conditional Formatting but this isn't what I'm looking for
I also know about opening the filter drop down, and clicking one cell, pressing down twice and pressing space bar (rinse and repeat) - but I'm not going to do this over 1000 rows...
Is there a way to alternate the colours from a filtered name in excel?
For example:
+---------------+---------------+--------------+
| Site Code | Site Name | Changed Date |
+---------------+---------------+--------------+
| 000020 | Bobs site | 28/11/18 | <-- colour 1
| 000020 | Bobs site | 26/11/18 | <-- colour 1
| 059201 | Julian's | date | <-- colour 2
| 059201 | Julian's | date | <-- colour 2
| 002237 | etc. 1 | date | <-- colour 1
| 523878 | etc. 2 | date | <-- colour 2
| 523878 | etc. 3 | date | <-- colour 2
+---------------+---------------+--------------+
So rather than by line number, it would be by the name "bobs site" would be one colour, the next in the list would be another colour etc
I would love for this to apply to site code and site name, so when filtering by either, the rows are highlighted correctly.
I can't do this in the =mod() kind of way, as some sites have just one entry, most have 2 and a few can have up to 10
EDIT: Proof of the answer working for future references
Doable with a helper column and Conditional Formatting with COUNTIF and MOD.
In the helper column:
=OR(A2<>A1,B2<>B1)
which returns TRUE or FALSE if the site code or site name has changed (or not) compared to the previous row.
Then 2 conditional formatting rules:
=MOD(COUNTIF($D$2:$D2,TRUE),2)=0
=MOD(COUNTIF($D$2:$D2,TRUE),2)=1
The mixed reference ($D$2:$D2) in the COUNTIF will allow for each separate section to be coloured alternately as the instances of TRUE are successively added up.
One solution; get all uniq values in a seperate column, copy column you want to refer to, paste to new column, remove duplicates.
Then select area with data and start refering those values you want to have that color i conditional formatting.
Edit
With more options use "AND" or "OR"
I have data in a spreadsheet like this
Name | 9/1/2016 | 9/2/2016 | .... | 6/8/2017
Abe | | | |
Jonas | | | |
I want to highlight every column where the date is either a weekend or a user defined date (for instance, a holiday....does excel already know federal holidays?).
The conditional format I have is:
Applies to
=$b$2:$KI$62
Format values where the following formula is true
#1 =WEEKDAY($B$1:$KI$1,1)=1
#2 =WEEKDAY($B$1:$KI$1,1)=7
Yet nothing shows up. At the best I've been able to only make the bottom row show up through playing with the function. Why?
With Name in A1, select B2 to the extents of your data and use the following to create a conditional formatting rule.
=WORKDAY(B$1-1, 1, $L$2:$L$4)<>B$1
I have a data set as follows:
A | B | C |...
1abc | 1def | 1ghi |...
2abc | 2def | 2ghi |...
...
This is a collection of memo notes for each account in our database. The 1 in "1abc" represents the account ID and the letters represent some text. There are a total of 177 columns and 1866 rows but not every row has values up to column 177, some may only have two columns worth of data.
I need each column to drop down to the bottom of column A so that all data only occupies Column A. For example, all the data in column B would inserted after the last value in A. Data in column C would be inserted after the last value in column A after it's been populated with the data from B and so on.
In the end, it should look something like this (from which point I can simply sort it in ascending order).
A | B | C |
1abc | | |
2abc | | |
...
1def | | |
2def | | |
...
1ghi | | |
2ghi | | |
...
Can anyone help out with this? I am assuming that I need a macro and have tried working with the solution found in this post but couldn't figure it out. Oh, and I'm using Excel 2003 if that helps.
I am not sure if this will help but, from what you have given me, it sounds like you have 3 columns of data that you would like to be put into one column. If I am correct in my thinking, you can do this a few different ways. So as to preserve the original document in its entirety while adding an extended sorting system you could: 1: Create new tab. Then highlight range a with your mouse. Using your mouse right click and select copy (try to keep in mind the value of the range, E.g. How many items have you copied. Paste it in your now tab. Do this for the remaining ranges. Or maybe use V look up. If you would like I have a schedule module I have created that has many different types of range associations. You can also split sting in excel to divide the id from the sting.
Without VBA, add a blank row at the top and a column on the left populated throughout with say x and then follow the steps detailed here. Then delete the left-hand two columns and filter the remaining one to remove any blanks.
I have a column of few thousand filenames that are not uniform. For instance:
| Column A | Column B |
===============================
| junk_City1_abunc | City1 |
-------------------------------
| nunk_City1_blahb | City1 |
-------------------------------
| small=City2_jdjf | City2 |
-------------------------------
| mozrmcity3_somet | City3 |
I would like to identify the city within the text in column A and return it in Column B.
I've come up with a complex formula that does the trick, but it is difficult to adjust if more cities are added within the filenames in new entries within column A.
Here is an example:
=IF(ISNA(MATCH("*"&$W$3&"*",I248,0)),IF(ISNA(MATCH("*"&$W$4&"*",I248,0)),IF(ISNA(MATCH("*"&$W$5&"*",I248,0)),IF(ISNA(MATCH("*"&$W$6&"*",I248,0)),IF(ISNA(MATCH("*"&$W$7&"*",I248,0)),IF(ISNA(MATCH("*"&$W$8&"*",I248,0)),"Austin","Orlando"),"Las Vegas"),"Chicago"),"Boston"),"Las Angeles"),"National")
It seems like there should be an easier way to do it, but I just can't figure it out.
(To make matters worse, not only am I identifying a city within the filename, I'm looking for other attributes to populate other columns)
Can anyone help?
Use the formula =IFERROR(LOOKUP(1E+100,SEARCH($E$2:$E$11,A2),$E$2:$E$11),A2)
This does *****NOT***** have to be array entered.
Where $E$2:$E$11 is the list of names you want returned and A2 is the cell to test
If no matches are found instead of errors you will just use the full name in column b.
If you want errors or expect to NEVER have then you can just use:
=LOOKUP(1E+100,SEARCH($E$2:$E$11,A2),$E$2:$E$11)
Here's a round about way that works, not all my own work but a mish mash of bits from other sources:
Assuming the sheet is setup as follows:
The formula to use is below, this must be entered using Ctrl+Shift+Enter
=INDEX($C$2:$C$8,MAX(IF(ISERROR(SEARCH($C$2:$C$8,A2)),-1,1)*(ROW($C$2:$C$8)-ROW($C$2)+1)))
Annotated version:
=INDEX([List of search terms],MAX(IF(ISERROR(SEARCH([List of search terms],[Cell to search])),-1,1)*(ROW([List of search terms])-ROW([Cell containing first search term])+1)))
Is it possible to filter an array using a single formula (without autofilter, VBA, or additional columns)?
For example, I have the following spreadsheet:
A | B | C
--------------------
1| ID | Class | Value
2| 1 | A | V1
3| 1 | B | V2
4| 2 | A | V3
5| 3 | B | V4
6| 3 | B | V5
I want to use a subset of this array in VLOOKUP. Namely, I only want to match against those rows where class is "B". So I was hoping I could use something like the following
=VLOOKUP(A3, FILTER_FUNC(A:C, B="B"), 3, false)
where FILTER_FUNC is some type of function or expression that returns an array that only contains those rows that meet the condition.
=VLOOKUP(A2,IF(B1:B3="B",A1:C3,""),1,FALSE)
Ctrl+Shift+Enter to enter.
This will do it if you only want the first "B" value, you can sub a cell address for "B" if you want to make it more generic.
=INDEX(A2:A6,SUMPRODUCT(MATCH(TRUE,(B2:B6)="B",0)),1)
To use this based on two columns, just concatenate inside the match:
=INDEX(A2:A6,SUMPRODUCT(MATCH(TRUE,(A2:A6&B2:B6)=("3"&"B"),0)),1)
Sounds like you're just trying to do a classic two-column lookup. http://www.dailydoseofexcel.com/archives/2009/04/21/vlookup-on-two-columns/
Tons of solutions for this, most simple is probably the following (which doesn't require an array formula):
=SUMPRODUCT((Lookup!A:A=Param!A1)*(Lookup!B:B=Param!B1)*(Lookup!C:C))
To translate your specific example, you would use:
=SUMPRODUCT((A1:A3=A2)*(B1:B3="B")*(C1:C3))
Today, in Office 365, Excel has so called 'array functions'.
The filter function does exactly what you want. No need to use CTRL+SHIFT+ENTER anymore, a simple enter will suffice.
In Office 365, your problem would be simply solved by using:
=VLOOKUP(A3, FILTER(A2:C6, B2:B6="B"), 3, FALSE)