Unique Values in Combobox, Leveraging Max Date from Another Range - excel

Question

I'm trying to teach myself VBA (primarily in Excel 2010) and I'm stuck on some code. I've leveraged sites such as Mr. Excel, Excel is Fun, and just about everywhere else that Google takes me, but I'm not having luck finding guidance that makes sense to me.
Challenge: I have a userform that has a combobox reading a range. The issue is, the sheet that the range exists on can have multiple duplicate values, but I only want to see unique values. To make it more challenging (to me), when the User selects a value in the combobox, I want that data set to flow back to the form.
I've managed to get data back on the form, but I'm having difficulty getting the MAX "Entered Date" record. So, if there are 5 instances of the name "Tom", with "Entered Dates" of 5/1/17, 6/1/17, 7/1/17, 8/17/17, 12/1/17; I want to see the record from 12/1/17.
It appears that I need to do something with a collection to get the unique value in the combobox, but I'm not understanding how it works. I also have no clue how to tie it all to the MAX "Entered Date". Here's the code that I have so far:
Private Sub cmd_Submit_Click()
Dim ws1 As Worksheet
Set ws1 = ThisWorkbook.Sheets("Client Measurements")
LastRow = ws1.Range("C" & Rows.Count).End(xlUp).Row + 1
ws1.Range("B" & LastRow) = Me.txt_Updated
ws1.Range("C" & LastRow) = Me.txt_First
ws1.Range("D" & LastRow) = Me.txt_Last
ws1.Range("E" & LastRow) = Me.txt_Suffix
ws1.Range("F" & LastRow) = Me.cobo_Name
ws1.Range("G" & LastRow) = Me.txt_EntryType
ws1.Range("H" & LastRow) = Me.txt_Height
ws1.Range("I" & LastRow) = Me.txt_Weight
ws1.Range("J" & LastRow) = Me.txt_Chest
ws1.Range("K" & LastRow) = Me.txt_Hips
ws1.Range("L" & LastRow) = Me.txt_Waist
ws1.Range("M" & LastRow) = Me.txt_BicepL
ws1.Range("N" & LastRow) = Me.txt_BicepR
ws1.Range("O" & LastRow) = Me.txt_ThighL
ws1.Range("P" & LastRow) = Me.txt_ThighR
ws1.Range("Q" & LastRow) = Me.txt_CalfL
ws1.Range("R" & LastRow) = Me.txt_CalfR
End Sub
Private Sub cobo_Name_DropButtonClick()
Dim i As Long
Dim coll As Collection
Dim ws1 As Worksheet
Set ws1 = ThisWorkbook.Sheets("Client Measurements")
LastRow = Sheets("Client Measurements").Range("F" & Rows.Count).End(xlUp).Row
For i = 2 To LastRow
If Sheets("Client Measurements").Cells(i, "F").Value = (Me.cobo_Name) Or _
Sheets("Client Measurements").Cells(i, "F").Value = Val(Me.cobo_Name) Then
Me.txt_First = Sheets("Client Measurements").Cells(i, "C").Value
Me.txt_Last = Sheets("Client Measurements").Cells(i, "D").Value
Me.txt_Suffix = Sheets("Client Measurements").Cells(i, "E").Value
Me.txt_Height = Sheets("Client Measurements").Cells(i, "H").Value
Me.txt_Weight = Sheets("Client Measurements").Cells(i, "I").Value
Me.txt_Chest = Sheets("Client Measurements").Cells(i, "J").Value
Me.txt_Hips = Sheets("Client Measurements").Cells(i, "K").Value
Me.txt_Waist = Sheets("Client Measurements").Cells(i, "L").Value
Me.txt_BicepL = Sheets("Client Measurements").Cells(i, "M").Value
Me.txt_BicepR = Sheets("Client Measurements").Cells(i, "N").Value
Me.txt_ThighL = Sheets("Client Measurements").Cells(i, "O").Value
Me.txt_ThighR = Sheets("Client Measurements").Cells(i, "P").Value
Me.txt_CalfL = Sheets("Client Measurements").Cells(i, "Q").Value
Me.txt_CalfR = Sheets("Client Measurements").Cells(i, "R").Value
End If
Next
End Sub
Private Sub UserForm_Initialize()
Dim ws1 As Worksheet
Dim cCMName As Range
Set ws1 = ThisWorkbook.Sheets("Client Measurements")
For Each cCMName In ws1.Range("CMName")
With Me.cobo_Name
.AddItem cCMName.Value
End With
Next cCMName
txt_EntryType = "Check In"
End Sub

Answer 1

Not an exact answer to your question, but an illustration of how you might go about it. This uses a Dictionary. You add a key and item pair and update the item if the new value in B is higher than the existing item.
Sub x()
Dim vData, r As Long
vData = Range("A1").CurrentRegion.Value
With CreateObject("Scripting.Dictionary")
For r = 1 To UBound(vData, 1)
If vData(r, 2) > .Item(vData(r, 1)) Then
.Item(vData(r, 1)) = vData(r, 2)
End If
Next r
Range("D1").Resize(.Count) = Application.Transpose(.keys)
Range("E1").Resize(.Count) = Application.Transpose(.items)
End With
End Sub

Answer 2

I'll be posting a new question in a separate thread, but realized that I never marked this one as answered. Here is the code that solved my problem:
Set coboDict = CreateObject("Scripting.Dictionary")
With coboDict
For Each cStatsClientID In ws1.Range("StatsClientID")
If Not .exists(cStatsClientID.Value) Then
.Add cStatsClientID.Value, cStatsClientID.Row
Else
If CLng(cStatsClientID.Offset(, -2).Value) > CLng(ws1.Range("B" & .Item(cStatsClientID.Value))) Then
.Item(cStatsClientID.Value) = cStatsClientID.Row
End If
End If
Next cStatsClientID
Me.cobo_ClientID.List = Application.Transpose(.keys)
End With