How to split one column to three column in excel? - excel

Question

How do i split the first picture(whole address) into second picture(address, city, state, zipcode). I have more than thousand data, so kindly suggest me the easy method?
All the whole address is formatted as 729 quail creek drive, frisco tx 75034
I need to split Address as 729 quail creek drive, City as frisco, State as tx and zipcode as 75034.
Thanks

Answer 1

If you know your data will always be of this format:
<address>, <city> <2-letter state> <5-digit zip code>
Then this is the easiest way I can think of:
Formula for <address>:
= LEFT(A1,FIND(",",A1)-1)
Formula for <city>:
= MID(A1,FIND(",",A1)+2,LEN(A1)-FIND(",",A1)-10)
Formula for <2-letter state>:
= MID(A1,LEN(A1)-7,2)
Formula for <5-digit zip code>:
= RIGHT(A1,5)
See below example.

Answer 2

This could be done with RegExp but instead of figuring out the RegExp pattern I've used the Split function and a couple of arrays. I've assumed that the Address is before the comma.
Sub SplitAddress()
Dim Addresses As Variant, results As Variant, tmp As Variant
Dim i As Long, j As Long
' Update for you range
With Sheet1
'Trick to get 1D array from range
Addresses = Application.Transpose(.Range(.Cells(2, "A"), .Cells(.Cells(.Rows.Count, "A").End(xlUp).Row, "A")))
End With
ReDim results(1 To UBound(Addresses), 1 To 4)
For i = 1 To UBound(results, 1)
tmp = Split(Addresses(i), ",")
results(i, 1) = Trim(tmp(0))
tmp = Split(Trim(tmp(1)), " ")
For j = LBound(tmp) To UBound(tmp)
results(i, j + 2) = Trim(tmp(j))
Next j
Next i
' Update for your destination
With Sheet1.Cells(2, "B")
Range(.Offset(0, 0), .Offset(UBound(results, 1) - 1, UBound(results, 2) - 1)).Value2 = results
End With
End Sub
Updated with RegExp
This method uses RegExp to split your strings
Sub splitAddressRegEx()
Dim ReGex As Object
Dim Addresses As Range
Dim j As Long
Dim c, m
' Update for your range
With Sheet1
Set Addresses = .Range(.Cells(2, "A"), .Cells(.Cells(.Rows.Count, "A").End(xlUp).Row, "A"))
End With
Set ReGex = CreateObject("VBScript.RegExp")
With ReGex
.Global = True
.IgnoreCase = True
.Pattern = "(.+?(?=,))|(\w+)"
End With
For Each c In Addresses
j = 1
If ReGex.Test(c.Value2) Then
For Each m In ReGex.Execute(c.Value2)
' Update for your output
c.Offset(0, j).Value2 = m
j = j + 1
Next m
End If
Next c
End Sub