How to get real Coordinates on QML-Map - python-3.x

Question

I have been trying to get the Map coordinates from my QML map with the MouseArea. But the problem is that I only get the coordinates of my mouse. It tells me the coordinates where the position of my mouse is on the window but not the coordinates of the click I made on the actual map. I don't know how to explain it better. Here is a part of my code:
MouseArea{
id: mouseArea
property var positionInRoot: mapFromItem(myItem, mouseX, mouseY)
anchors.fill: parent
acceptedButtons: Qt.LeftButton
hoverEnabled: true
onClicked: {
console.warn("Coordinates: " + mouseArea.positionInRoot)
}
}
My Question is now if it's possible to get the coordinates of the map where I made a mouseclick? And if yes how could I do it?

Answer 1

You should use the toCoordinate method of the QML map.
mapFromItem / mapToItem are used to map a point in a item to another item's coordinate system, but we're talking about QML Item's (x, y) and not QtPosition latitude, longitude. You still need those however, if your MouseArea and Map do not have the same x/y position
Here is an example that display a label with lat and lon under the mouse cursor.
Map {
id: map
anchors.fill: parent
plugin: mapPlugin
}
MouseArea
{
anchors.fill: map
hoverEnabled: true
property var coordinate: map.toCoordinate(Qt.point(mouseX, mouseY))
Label
{
x: parent.mouseX - width
y: parent.mouseY - height - 5
text: "lat: %1; lon:%2".arg(parent.coordinate.latitude).arg(parent.coordinate.longitude)
}
}
If you want to display coordinates in degrees minutes second format, you could use helper such as these:
function decimalToMinutes(value, isLat)
{
var letter = isLat?value>=0?"N":"S":value>=0?"E":"W"
var degrees = Math.floor(value)
var minutes = Math.floor((value-degrees)*60)
var seconds = ((value-degrees)*3600 - 60*minutes).toFixed(1)
return "%1° %2' %3\" %4".arg(degrees).arg(minutes).arg(seconds).arg(letter)
}
function minutesToDecimal(value)
{
var myRegexp = /(\d+)° (\d+)' (\d+(?:\.\d+)?)" ([NSEW])/g;
var match = myRegexp.exec(value)
if(match == null)
return 0
return ((match[4]=="N"||match[4]=="E")?1:-1)*(Number(match[1]) +Number( match[2]/60) + Number(match[3]/3600))
}
function coordinateToString(coordinate)
{
return decimalToMinutes(coordinate.latitude, true) + " " + decimalToMinutes(coordinate.longitude, false)
}