Identify empty "Range" after it is deleted - excel

Question

I work with Ranges and sometimes all cells in a given object are deleted (Range.Cells.Delete)
I've played around and find these:
after deleting all cells, type of the variable is still Range and it Is Not Nothing
calling any of it's members results in Error "Object required"
Here is my small sub to test it:
Sub test()
Dim r As Range
Debug.Print r Is Nothing ' -> true
Set r = ActiveSheet.Range("a2")
Debug.Print TypeName(r) ' -> Range
r.Cells.Delete shift:=xlShiftUp
On Error GoTo ErrHandler
Debug.Print r Is Nothing ' -> False
Debug.Print TypeName(r) ' -> Range
Debug.Print r.Address ' -> "Err: Object required"
Debug.Print r.Cells.Count ' -> "Err: Object required"
Exit Sub
ErrHandler:
MsgBox "Err: " & Err.Description
Resume Next
End Sub
My question is: how can I determine (hopefully without error handling) whether an object is an empty Range?
Shortest option I've found so far:
Function IsEmptyRange(testRange As Range) As Boolean
If TypeName(testRange) <> "Range" Then
IsEmptyRange = False
Else
On Error GoTo EmptyRange
IsEmptyRange = testRange.Cells.Count = 0
If False Then
EmptyRange:
Err.Clear
IsEmptyRange = True
End If
End If
End Function

Answer 1

There's an interesting discussion about this on Daily Dose of Excel pointing to a similar Stack Overflow question. The DDoE doesn't give a 'solution' but the discussion is illuminating regarding 'expected behaviour'. The SO post does (by #DougGlancy) but it is just a version of your code (perhaps slightly better because no If False Then... construct required).
IMO the best practice here is to remember to set your reference variables to Nothing if, and when, you can. E.g.
Sub test()
Dim r As Range
Debug.Print r Is Nothing ' -> true
Set r = ActiveSheet.Range("a2")
Debug.Print TypeName(r) ' -> Range
r.Cells.Delete shift:=xlShiftUp
Set r = Nothing ' -> end of problem
On Error GoTo ErrHandler
Debug.Print r Is Nothing ' -> True
If Not r Is Nothing Then
Debug.Print TypeName(r) ' -> Range
Debug.Print r.Address ' -> "Err: Object required"
Debug.Print r.Cells.Count ' -> "Err: Object required"
End If
Exit Sub
ErrHandler:
MsgBox "Err: " & Err.Description
Resume Next
End Sub
The tendency is probably to let scope deal with the clean-up (i.e. r will go out of scope once the Sub is complete) but it is better to do the clean-up yourself.

Answer 2

In my case I don't have any loop, therefore For ... Step -1, as Nigel Heffernan says, is not a solution.
With this problem the correct solution will depend on the context.
This is mine:
Sub test()
'Mi context: from C2 all the cells are empty
Dim Rng As Range
Set Rng = ActiveSheet.Range("A2:B2")
'trim all cells in Rng
Rng = Application.Trim(Rng.Value)
'I use CountIf instead xlCellTypeBlanks because it
'would give an error if there are no empty cells
If WorksheetFunction.CountIf(Rng, "") > 0 Then
'delete all empty cells in Rng
Rng.SpecialCells(xlCellTypeBlanks).Delete Shift:=xlToLeft
End If
'Assign Rng again
Set Rng = ActiveSheet.Range("A2:B2")
'and check again if all cells are empty
If WorksheetFunction.CountIf(Rng, "") = Rng.Cells.Count Then
MsgBox """A2:B2"" range have been deleted"
Else
'do something
End If
End Sub
In other contexts you can store the initial values ​​of Rng and, after deleting cells in the range, compare with the newly assigned Rng