How to reflect dates on specific cells corresponding to a list item chosen in Excel? - excel

Question

Basically I have an excel sheet used for tracking statuses in hiring, where there are around 5 statuses (Briefing, Advertising, Shortlisting, Selection, Offering) and against each vacancy there's a status cell as a list of the above statuses and it's changed manually based on the status of the vacancy.
I have found a vba code (attached below) to reflect in a certain cell the date that the status has been changed, and if I choose another status (basically update the status) it overwrites the previous input, but what I need to do is a bit more complicated.
I created a column for each status and I need this code to reflect the date on each status's cell corresponding to the one I have chosen from the list, for example, choosing briefing for a specific vacancy will reflect the date on the corresponding cell in the "briefing" column, and if I change the status for that specific vacancy from the list to "selection", a date will reflect on the corresponding cell in the "selection" column.
The code that I've found so far is below:
Private Sub Worksheet_Change(ByVal Target As Range)
'Update 20140722
Dim WorkRng As Range
Dim Rng As Range
Dim xOffsetColumn As Integer
Set WorkRng = Intersect(Application.ActiveSheet.Range("N:N"), Target)
xOffsetColumn = 1
If Not WorkRng Is Nothing Then
Application.EnableEvents = False
For Each Rng In WorkRng
If Not VBA.IsEmpty(Rng.Value) Then
Rng.Offset(0, xOffsetColumn).Value = Now
Rng.Offset(0, xOffsetColumn).NumberFormat = "dd-mm-yyyy"
Else
Rng.Offset(0, xOffsetColumn).ClearContents
End If
Next
Application.EnableEvents = True
End If
End Sub

Answer 1

You can modify your code and add Select Case Statement to adjust column offset depending on data entry:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim WorkRng As Range
Dim Rng As Range
Dim xOffsetColumn As Long
Set WorkRng = Intersect(Application.ActiveSheet.Range("N:N"), Target)
If Not WorkRng Is Nothing Then
Application.EnableEvents = False
For Each Rng In WorkRng
Select Case Rng.Value2
Case "Briefing"
xOffsetColumn = 1 'Column O
Case "Advertising"
xOffsetColumn = 2 'Column P
Case "Shortlisting"
xOffsetColumn = 3 'Column Q
Case "Selection"
xOffsetColumn = 4 'Column R
Case "Offering"
xOffsetColumn = 5 'Column S
Case Else
xOffsetColumn = 6 'Column T - entry not listed above
End Select
Rng.Offset(0, xOffsetColumn).Value = Now
Rng.Offset(0, xOffsetColumn).NumberFormat = "dd-mm-yyyy"
Next
Application.EnableEvents = True
End If
End Sub