To convert upper case to lower case of same word in qbasic - basic

Question

Hi there i want to get idea or code for converting uppercase into lowercase and lowercase into uppercase of same word for eg: convert StAcKOVERfloW to sTaCkoverFLOw please can any one give me idea or the code for qbasic programming language

Answer 1

The way to solve this task is to process the characters in the string one after the other. A basic FOR NEXT loop accomplishes this:
FOR cpos% = 1 TO LEN(text$)
char$ = MID$(text$, cpos%, 1) ' Extracts 1 character at the current position
...
NEXT
QBasic has the UCASE and LCASE functions that will convert their string argument into uppercase and lowercase respectively. If the string we deal with consists of a single word with nothing but uppercase and lowercase characters, next code snippet will produce the desired result:
text$ = "StAcKOVERfloW"
PRINT text$;
FOR cpos% = 1 TO LEN(text$)
char$ = MID$(text$, cpos%, 1)
IF char$ >= "A" AND char$ <= "Z" THEN
MID$(text$, cpos%) = LCASE$(char$)
ELSE
MID$(text$, cpos%) = UCASE$(char$)
END IF
NEXT
PRINT " --> "; text$
We can write the above code without using UCASE or LCASE. Then we will be dealing with the ASCII codes of the characters. The uppercase characters "A" to "Z" have ASCII codes 65 to 90, and the lowercase characters "a" to "z" have ASCII codes 97 to 122. These ranges are 32 apart and that's an important number for the conversion from one in the other.
Next version works this way:
text$ = "StAcKOVERfloW"
PRINT text$;
FOR cpos% = 1 TO LEN(text$)
char$ = MID$(text$, cpos%, 1)
IF char$ >= "A" AND char$ <= "Z" THEN
MID$(text$, cpos%) = CHR$(ASC(char$) + 32) ' Upper to Lower means + 32
ELSE
MID$(text$, cpos%) = CHR$(ASC(char$) - 32) ' Lower to Upper means - 32
END IF
NEXT
PRINT " --> "; text$
This move to using the ASCII code will allow us to write the conversion in a single line. It's the XOR operator that does the heavy lifting here. We no longer need to decide about adding 32 or subtracting 32. The exclusive OR does the toggle for us:
text$ = "StAcKOVERfloW"
PRINT text$;
FOR cpos% = 1 TO LEN(text$)
MID$(text$, cpos%) = CHR$(ASC(MID$(text$, cpos%, 1)) XOR 32)
NEXT
PRINT " --> "; text$
For a general solution to the problem of toggling the case of characters, we have to take into consideration that the user at the keyboard could be inputting an empty text, and that the text could turn out to contain characters that are not uppercase or lowercase letters.
To guard against an empty text, we can replace FOR NEXT by WHILE WEND where the condition is such that the loop is skipped if the current position cpos% does not exist in the string text$.
Because all modification to the string happens conditionally, there's no danger of modifying anything else than letters.
INPUT ; "Text : ", text$
cpos% = 1
WHILE cpos% <= LEN(text$)
ascii% = ASC(MID$(text$, cpos%, 1))
ucase% = ascii% AND &HDF
IF ucase% >= 65 AND ucase% <= 90 THEN
MID$(text$, cpos%) = CHR$(ascii% XOR 32)
END IF
cpos% = cpos% + 1
WEND
PRINT " --> "; text$
The code is 'optimized' in the way that it favors using numerical operations over using string operations. In general it is true that string assignments take a relatively long time.
The code first converts the ASCII code to uppercase so as to simplify the IF from
IF (ascii% >= 65 AND ascii% <= 90) or (ascii% >=97 and ascii% <=122) THEN
to
ucase% = ascii% AND &HDF
IF ucase% >= 65 AND ucase% <= 90 THEN