Instantiating ActiveX Controls in a worksheet using vba - excel

Question

I am trying to create a tool in Excel. My first problem is that I cannot reliably instantiate labels and textboxes on my worksheet. I currently have the code below.
Sub Test2()
Dim Schedule As Worksheet
Set Schedule = Worksheets("Schedule")
'Creates the row number
Schedule.OLEObjects.Add ClassType:="Forms.Label.1"
With Worksheets("Schedule").Label1
.Caption = 1
.width = 18
.Height = 18
.Top = 0
.Left = 0
.SpecialEffect = 1
.BackColor = &H8000000F
.TextAlign = 2
End With
End Sub
and
Sub Test3()
Dim Schedule As Worksheet
Set Schedule = Worksheets("Schedule")
Schedule.OLEObjects.Add ClassType:="Forms.TextBox.1"
With Worksheets("Schedule").TextBox1
.Text = "Task Name"
.width = 200
.Height = 18
.Top = 0
.Left = 18
.SpecialEffect = 0
.BackColor = &H80000005
.TextAlign = 1
.BorderStyle = 1
End With
End Sub
These both work on their own, but when you run one then the other an error is generated
"Run-time error '438': Object doesn't support this property or method".
Any advice?
Also, how would I store and access these labels and text boxes if I have an indefinite amount being created, I assume some sort of collect?

Answer 1

For some of the properties, you'll need to refer to the Object property of the OleoObject object...
Sub Test2()
'Creates the row number
With Worksheets("Schedule").OLEObjects.Add(ClassType:="Forms.Label.1")
.Left = 0
.Top = 0
.Width = 18
.Height = 18
With .Object
.Caption = 1
.SpecialEffect = 1
.BackColor = &H8000000F
.TextAlign = 2
End With
End With
End Sub
Sub Test3()
With Worksheets("Schedule").OLEObjects.Add(ClassType:="Forms.TextBox.1")
.Left = 18
.Top = 0
.Width = 200
.Height = 18
With .Object
.Text = "Task Name"
.SpecialEffect = 0
.BackColor = &H80000005
.TextAlign = 1
.BorderStyle = 1
End With
End With
End Sub
Hope this helps!