Hide excel columns doesn't work in outlook vba - excel

Question

I simply can't find a way to hide specific columns in outlook vba. I tried everything. My current code is the following:
Sub ExportToExcel()
Dim xlApp As Object
Dim xlWB As Object
Dim xlSheet As Object
Dim enviro As String
Dim strPath As String
Dim ns As NameSpace
Dim item As Object
Dim inbox As MAPIFolder
Dim i As Long
Dim j As Long
' Get Excel set up
enviro = CStr(Environ("USERPROFILE"))
'the path of the workbook
strPath = enviro & "\Documents\test.xlsx"
On Error Resume Next
Set xlApp = GetObject(, "Excel.Application")
If Err <> 0 Then
Application.StatusBar = "Please wait while Excel source is opened ... "
Set xlApp = CreateObject("Excel.Application")
bXStarted = True
End If
On Error GoTo 0
'Open the workbook to input the data
Set xlWB = xlApp.Workbooks.Open(strPath)
Set xlSheet = xlWB.Sheets("Sheet1")
' Process the message record
`On Error Resume Next
For j = 2 To 367
If xlSheet.cells(1, j).Value <> Date And xlSheet.cells(1, j).Interior.ColorIndex = 4 Then
xlSheet.Columns(j).Interior.ColorIndex = 0
End If
If xlSheet.cells(1, j).Value = Date Then
xlSheet.Columns(j).Interior.ColorIndex = 4
For i = 2 To j - 1
xlSheet.Columns(i).EntireColumn.Hidden = True
Debug.Print xlSheet.cells(1, i).Value
Next i
Exit For
End If
Next j
xlWB.Worksheets("Sheet1").Columns("A:NB").EntireColumn.AutoFit
xlWB.Close 1
If bXStarted Then
xlApp.Quit
End If
End Sub
The 1st row, starting from the 2nd column of my excel sheet is populated with dates starting from 01.01.2017 and up to 31.12.2017.
I want the macro to hide all dates from before the current day.
As you can see, the debug.print in the test for hiding works as intended and prints all dates from 01.01.2017 to current date-1.
As a side note, xlSheet.Columns(i).Color = 5287936 did not work either.
By placing the On Error Resume Next from before the for in comments, I get an "Application-defined or object-defined error" error.
If I remove all the error tests, I get an "ActiveX component can't create object" error.
New finding, if I debug.print xlsheet.columns(i).hidden I get a "true" message in the immediate window. Apparently the code does exactly what it's supposed to, but it just doesn't take effect.

Answer 1

Try Autofit manually. You should find it unhides hidden columns.
Move Autofit so it is before the columns are hidden or be more precise about the columns to autofit.
Set xlWB = xlApp.Workbooks.Open(strPath)
Set xlSheet = xlWB.Sheets("Sheet1")
xlWB.Worksheets("Sheet1").Columns("A:NB").EntireColumn.AutoFit
' Process the message record
For j = 2 To 367
If xlSheet.Cells(1, j).Value <> Date And xlSheet.Cells(1, j).Interior.ColorIndex = 4 Then
xlSheet.Columns(j).Interior.ColorIndex = 0
End If
If xlSheet.Cells(1, j).Value <> Date And xlSheet.Cells(1, j).Interior.ColorIndex <> 0 Then
xlSheet.Columns(j).Interior.ColorIndex = 4
End If
If xlSheet.Cells(1, j).Value = Date Then
xlSheet.Columns(j).Interior.ColorIndex = 4
For i = 2 To j - 1
xlSheet.Columns(i).EntireColumn.Hidden = True
Debug.Print xlSheet.Cells(1, i).Value
Next i
Exit For
End If
Next j