Creating a table based upon number of rows/columns entered - excel

Question

I want to be able to build a table based upon the answer to 2 questions, with Question 1 "How many risks are in the current process?" to determine the number of columns (i.e. one per risk) and the second question "How many controls in the current process?" determines the number of rows to use (i.e one per control). Is there an easy way to build a table to show a matrix that can then be used for risk/control relationships?

Answer 1

This was a fun one, so I'll plan to make a YouTube tutorial on this later tonight and come back here to post my link. But here's a quick explanation of what I did.
I started by using A2 cell for # of rows, and the B2 cell for # of columns. Then I created a button of which I will assign it to a macro, explained in a bit.
Next I created the base layout for the table. This includes:
D5 to hold "Control ID"
E5 to hold "Control Description"
F3 to hold "Risk ID"
F4 to hold "Risk Description"
Also, let's start by adding the first Control and Risk blocks, as every table would presumably start with at least 1 control and 1 risk. So
D6 will have "C1"
E6 will have "Control 1 Description"
G3 will have "R1"
G4 will have "Risk 1 Description"
Then to keep consistent with your table, I put a black highlight on cells F5 and G5.
Now we can create the macro, using the following code:
Sub CreateTable()
' create variable x to hold # of rows from A2
Dim x As Integer
x = Range("A2").Value
' calculate the row range from x
Let RowRange = "7:" & 7 + x - 2
' copy row 6 into each row in the calculated range
Rows("6:6").Copy Range(RowRange)
' update the text in the newly created rows to match
' the corresponding control number
For i = 2 To x
Let ControlIdRow = 5 + i
Cells(ControlIdRow, 4).Value = "C" & i
Cells(ControlIdRow, 5).Value = "Control " & i & " Description"
Next i
Dim y As Integer
y = Range("B2").Value
Columns("G:G").Copy Range(Columns(8), Columns(8 + y - 2))
For i = 2 To y
Let RiskIdCol = 6 + i
Cells(3, RiskIdCol).Value = "R" & i
Cells(4, RiskIdCol).Value = "Risk " & i & " Description"
Next i
End Sub
Basically what's happening is that we create a variable x and assign it to be the number of rows, as input from cell A2. Then we use that to calculate the row range starting at row 7 (which will start as Control 2 since Control 1 is on row 6). Then we just copy the entire row 6 up until the specified range. Now (starting at the For loop), we need to edit the text in the cells to match the corresponding names (i.e. the second control will be C2, Control 2 Description, the third will be C3, Control 3 Description 3, and so on). Then just essentially repeat that same block, changing the respective values to match the Risks.
Then don't forget to assign the button to the new macro. Now you should be able to enter in a value for rows (A2) and a value for columns (B2) and click the button, and it should automatically create the table for you.
As mentioned, I'll create a YouTube video later tonight detailing this more and update this answer to point there.
Update
I noticed your picture has a checkmark in it, so here's the code to be able to just select a cell and have a green checkmark appear in the cell. Then clicking the cell again will remove the checkmark.
Open up the visual basic editor, and click the Sheet 1 code from the left. Then apply the following code in there:
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If ActiveCell.Row > 5 And ActiveCell.Column > 6 Then
If ActiveCell.Value = "" Then
Target.Value = ChrW(&H2713)
Else
If ActiveCell.Value = ChrW(&H2713) Then
Target.Value = ""
End If
End If
End If
End Sub
Link to YouTube Tutorial on this answer