Good afternoon.
I have an Excel Question
How to get from this to this.
A DFG
A ASD
C DD
A 144
C XX
B $%
------------
A DFG ASD 144
B $%
C XX DD
I tried with Index but I am not able to get the desired results.
Any idea>
Thanks
If your data is in columns A and B, then try:
F7: =IFERROR(INDEX($B:$B,AGGREGATE(15,6,1/1/($A:$A=$E7)*ROW($A:$A),COLUMNS($A:A))),"")
Fill down and to the right as needed (until you see blanks)
where G7 contains the item in column A you are looking for
Related
Hi,
I would like to investigate a huge list that I can distinguish the Acc numbers according to the mail adresses. The things that I
would like to do if email adresses has a seperate Acc and if they
equal each other( I mean if Acc numbers are equal),write a "equal" if
the criterias were not equal with the same email then write a
"multiple criteria"..
Is there any way to do that with Excel formulas or VBA ?
Mail Acc
uralsmh#gmail.com C1234
uralsmh#gmail.com C2345
Part 1 - check for duplicates
Create a helper column that sticks columns A and B together and then count this column. You can use the & character for this:
A B C D
1 abc 123 =A1&B1 =COUNTIF($C$1:$C$1000,C1)
2 abc 123 =A2&C2 =COUNTIF($C$1:$C$1000,C2)
3 def 123 =A3&C3 =COUNTIF($C$1:$C$1000,C3)
If you get a number greater than 1 in column D, then that row is a duplicate of another row.
Part 2 - find multiple accounts
Now you have found the exact duplicates, any email addresses that match must have different account numbers. So, in column E, just count column A:
A B C D E
1 abc 123 =A1&B1 =COUNTIF($C$1:$C$1000,C1) =COUNTIF($A$1:$A$1000,A1)
2 abc 123 =A2&C2 =COUNTIF($C$1:$C$1000,C2) =COUNTIF($A$1:$A$1000,A2)
3 def 123 =A3&C3 =COUNTIF($C$1:$C$1000,C3) =COUNTIF($A$1:$A$1000,A3)
If you get a number greater than 1 in column E and you had a 1 in column D, you have found an email address with multiple accounts.
I have a spreadsheet in this format:
A B C
11 Trailers Trailer Builders
19 Trailers Erde Trailers
I'd like to append every value in the column B with the following characters ->, I'd also like append every value in the column C with a $. What is the best solution for this in Excel?
My output should look like this:
A B C
11 Trailers-> Trailer Builders$
19 Trailers-> Erde Trailers$
You can do D2 as =CONCATENATE(B2,"->") and E2 as =CONCATENATE(C2,"$",) to get this value.
So here it is,
Column A has duplicate and unique number values, Column B has duplicate and unique Strings (Names). I need to count the instances of unique number values in A matched to their name in B.
So it would be like =COUNTIF(B1:B100,"XYZ") "Then counts all unique number values in A1:A100 that "match" or have XYZ in column B.
Col A - Col B
ABC - 963
ABC - 963
FFF - 367
FFF - 367
FFF - 234
XYZ - 678
XYZ - 221
XYZ - 334
What I need:
ABC = 1 ( one unique instance where Col A and Col B (ABC,963) )
XYZ = 3 ( three unique instances (XYZ,678 : XYZ,221 : XYZ,334
FFF = 2 ( two unique instances ( FFF,367 and FFF, 234 )
So I need to sum up all the unique instances of Column A that only match the strings in column B.
Thanks in advance !, I'll keep searching in the meantime !
I believe that you are looking to retrieve a count of the unique combinations of number and name. Perhaps something like the following.
The formula in E2 is,
=SUMPRODUCT((A$2:A$99<>"")/COUNTIFS(B$2:B$99, B$2:B$99&"", A$2:A$99, A$2:A$99&""))
The formula in E4 is,
=SUMPRODUCT((A$2:A$99=D4)/COUNTIFS(B$2:B$99, B$2:B$99&"", A$2:A$99, A$2:A$99&""))
Fill E4 down as necessary.
I have 4 columns, containing 2 columns of names and 2 columns of values, as below. I need to update Column B with value in K, if the name1 = name2. Both name columns are formatted as text, and values columns are formatted as numeric.
(A) Name1 (B) Value1 (J) Name2 (K) Value2
A A 123
B B 456
C X 000
D Y 000
E Z 000
F C 789
I insterted the following vlookup in the first row of column B, but it returns the name in column A.
=VLOOKUP(A4,J2:J22890,K2:K22890)
I'm expecting to have the following result:
(A) Name1 (B) Value1 (J) Name2 (K) Value2
A 123 A 123
B 456 X 000
C 789 B 456
D Y 000
E Z 000
F C 789
Am I using vlookup a the wrong way? or is it due to the fact that I'm looking up strings??
I think it should be
=VLOOKUP(A4,J2:K22890,2,0)
1.First parameter is the value you are looking for,
2.second one is the range (it can be multiple columns, with the referenced data in the most-left column of the selection),
3.followed by the column's number where the records should be retrieved from,
4.and lastly a flag (1 or 0) if you would like to accept similar results (1) or exact matches only (0)
Since I can't edit the post because it's not enough characters and I can't comment because I don't have enough rep...
=VLOOKUP(A4,$J$2:$K$22890,2,0)
This is Alex's post with absolute references for the lookup table array.
I want to compute the average over one column if the text in another column matches a certain text.
eg:
A B C
aa 6 =AVERAGEIF(B1:B6;EXACT(A1:A6;"aa"))
bb 15
aa 8
bb 17
cc 1
aa 5
But the value in C gets 1. Why? How can I do what I want?
I would suggest using the AVERAGEIFS() function instead of AVERAGEIF(). See below:
=AVERAGEIFS(B1:B6,A1:A6,"aa")
This will yield as result of 6.3333.
Cheers.