I want to Select Some cells of A column and convert those into one single cell on a column And add The , or / Character between of every cells data.
For example Please see my picture.
I Have selected some cells in a column and want to convert or merge those to single cell with / separated cells data.
Picture:
I am very amateur in Excel. Please give me a guidance for step by step convert.
In Excel 2016 you can use a new function called Textjoin() with the syntax
=Textjoin(delimiter, ignore empty text, range to join)
From your screenshot it seems that you want to join the text from rows 12 to 15 in each column, so the formula would be
=Textjoin("/",true,B12:B15)
Copy that formula to the right.
In earlier versions of Excel you can use
=B12&"/"&B13&"/"&B14&"/"&B15
and copy to the right.
By the way, it would make our task of helping you a little bit easier if the sample screenshot shows English instead of Arabic, because with Arabic, most of us will be forced to compare the pictorials, since most of us can't read Arabic as easily as English.
Related
I've two excel files having data and each having four columns. I need to compare the two excels and it should show me the difference for each row.
To achieve this, I'm thinking of:
Using a VLookup feature
or
Writing Python code to achieve this.
Was wondering if there is any other better approach for this please?
Thank you.
Just an idea.
Here is an example of how you could use the =IF function to compare two Excel files:
1. Open both Excel files in separate tabs in Excel.
2. In the first Excel file, select the cell where you want to display the result of the comparison.
3. Type the =IF function in the selected cell, followed by the cell reference for the corresponding cell in the second Excel file. For example, if you want to compare the values in cell A1 of the first Excel file with cell A1 of the second Excel file, you would type =IF(A1=Sheet2!A1, "Match", "Difference") in the selected cell.
4. Press Enter to execute the =IF function and display the result of the comparison. If the values in the two cells are the same, the =IF function will display "Match". If the values are different, the =IF function will display "Difference".
5. Repeat the above steps for each cell that you want to compare in the two Excel files. And when you've done it to two you mgiht be able to select the two created IF's and drag it down so it will fill out the rest (if you someday have more than 4 columns).
I am trying to highlight cells in column G based off of whether or not the cell contains any of the text strings I have entered into another table, specifically the Pgroup table in Column U. I would like this to become a flexible conditional format based on text strings that can be added to or subtracted from the secondary table based on a project basis. I have tried a couple different ways but to no avail. Any help would be appreciated. I know I can enter another condition for every text string but thought this would be a better alternative since my text strings can change regularly. I am trying to do this with different columns and different reference tables as well but if I can find a way to make it work with one I think it will work with all. Not all will be absolute matches, I'd also like to be able to search for text strings inside of a cell that contains more than just the text string I'm looking for.
My File
Conditional formatting --> New Rule --> Formula -->=SUM(COUNTIF($A2,$P$2:$P$7))
Where A2 is the start of a column to format and P2:P7 is where your values are located.
To format the whole row, set "Applies to" to $A$2:$endOfYourTable
I am trying to combine several excel columns and separate the data with a comma. Some cells are blank so I want to avoid adding unnecessary commas. How do I add a conditional that says "if the cell is blank don't attempt to add the data and another comma"? The output I am looking for is on the right. I am trying to perform this on a large dataset and the number of columns for each row is variable. The only time a blank cell will be encountered is at the end of the row.
I have tried basic concatenate and am using excel 2010.
just copy and paste the following formula in your result column.
=IF(ISBLANK(A1),"", CONCATENATE(A1,IF(ISBLANK(B1),"", CONCATENATE(CONCATENATE(",",B1),IF(ISBLANK(C1),"", CONCATENATE(CONCATENATE(",",C1),IF(ISBLANK(D1),"", CONCATENATE(",",D1))))))))
This works fine for your first 4 columns (atleast in Excel 2016:), however this is not a recommended solution as you have mentioned that you're working with a large dataset, but might help you!
I have a workbook created in Excel 2013 that every engineer at my job has to use to check data that was input into a system. We are able to export the files into XLS, and I created a macro to pull all the data and conditional formatting to display "errors" that need to be fixed.
We are in the process of versioning the workbook, and to do so I am trying to get some more complicated formulas out there to check the data. There are several columns that need to be cross checked in one check, because they should match. This means i need a formatting rule to look in any given cell in a column, and check other cells in the SAME ROW, but DIFFERENT COLUMN, and make sure they match..
For example:
Column A is Label ID Text, and in this case it says 1 - 1.5" HDPE.
Column B is the Duct Count, which is 1
Column C is the Duct Size, which is 1.5"
and Column D is the Duct Type, which is HDPE.
I the Label ID text to take the 3 separate parts of the string, and match it to other columns. If it doesn't it highlights the column B-D that doesn't match. I manually created an example of what I need it to do.
Example:
So this involves working with strings, specifically the functions LEFT, RIGHT, MID, and also being mindful of how you're comparing items.
It all involves being meticulous in how you're separating the values from the string in your first column. In order to test all your function, start using empty cells to slowly build up the formulas to assemble the overall logic.
In figuring out your duct count, you can see you want "the number to the left of the dash character". So you'll start this way...
=FIND("-",A2)
You only want the characters to the left of the dash, so use the LEFT function
=LEFT(A2,FIND("-",A2))
Which returns a value of 1 -, but you don't want to include the dash, so subtract one.
=LEFT(A2,FIND("-",A2)-1)
Now if you compare this value to your Duct Count in column B, you'll get
=LEFT(A2,FIND("-",A2))=B2
Which gives a value of FALSE. This is because the result of the LEFT function you built is a string "1 " and not a number. So use another function to convert it to a number
=NUMBERVALUE(LEFT(A2,FIND("-",A2)-1))=B2
Now you get the correct result of TRUE.
So highlight cells B2:B5 and select Conditional Formatting-->New Rule. Then choose "Use a formula to determine which cells to format". Then type in your formula (the whole =NUMBERVALUE thing) and select your format. And you're done with that column.
Continue to work out how to separate the values for the other columns. If you have more questions we can help.
Please clear any existing CF from ColumnsB:D, select them and HOME > Styles - Conditional Formatting, New Rule..., Use a formula to determine which cells to format and Format values where this formula is true::
=NOT(OR(B1=--LEFT($A1,FIND("-",$A1)-2),B1=MID($A1,FIND("-",$A1)+2,FIND("-",$A1)+1),B1=MID($A1,FIND("""",$A1)+2,LEN($A1))))
Format..., select choice of formatting, OK, OK.
I want a macro to find all the words written a column in another excel & make them bold.
For EX: I have Words like new, grow, etc written in a column B of Excel an the macro has to Find theses words individually in another excel & make them bold and change the Background of the cell to Red Color.
Thanks in Advance.
You may want to have a look into conditionnal formatting.
Assume for example you have the values you want to look for in column B, and you want to highlight all values in a range, say, D4:F15.
Select the range D4:F15, make a new formatting rule and choose "Use a formula to determine which cells to format". Enter =ISNUMBER(MATCH(D4;$B:$B)) as formula, and make the format as you wish. Note that D4 in the formula has to be the first cell of the range.
If you don't need more than that, the benefit is that you don't need a macro at all, and the formatting can be done in real time too.