Need some help understanding Application.Transpose() - excel

Question

Could someone explain what is happening here? Preferably line for line. I am having a hard time wrapping my head around what is happening with this bit.
a = Application.Transpose(a)
For i = 1 To UBound(a, 2)
If UCase(a(1, i)) Like "*" & temp & "*" Or _
UCase(a(2, i)) Like "*" & temp & "*" Then
n = n + 1
For ii = 1 To UBound(a, 1)
a(ii, n) = a(ii, i)
Next
End If
Next
I am also experiencing a "type mismatch" error for the above. See full Sub below.
Private Sub TextBox_Search_Change()
Select Case True
Case OptionButton_User_Name.Value
Dim a, i As Long, ii As Long, n As Long, temp As String
If Len(Me.TextBox_Search.Value) Then
temp = UCase(Me.TextBox_Search.Value)
With Sheets("ToolData")
a = Union(.Range("B:B"), .Range("F:F"), .Range("G:G")).Value
End With
a = Application.Transpose(a)
For i = 1 To UBound(a, 2)
If UCase(a(1, i)) Like "*" & temp & "*" Or _
UCase(a(2, i)) Like "*" & temp & "*" Then
n = n + 1
For ii = 1 To UBound(a, 1)
a(ii, n) = a(ii, i)
Next
End If
Next
If n > 0 Then
ReDim Preserve a(1 To UBound(a, 1), 1 To n)
Me.ListBox_History.Column = a
End If
Else
With Sheets("ToolData")
Me.ListBox_History.List = Union(.Range("B:B"), .Range("F:F"), .Range("G:G")).Value
End With
End If
Case Else
End Select

Answer 1

You cannot use .Value on a multi-area range: you will only get values from the first column (B).

Answer 2

I would refactor the True portion of your If statement as
temp = UCase(Me.TextBox_Search.Value)
Dim rngValues As Variant
With Sheets("ToolData")
rngValues = .Range("B2", .Range("B" & .Rows.Count).End(xlUp)).Resize(, 6).Value
End With
For i = 1 To UBound(rngValues, 1)
'Check columns B & F for matching values
If UCase(rngValues(i, 1)) Like "*" & temp & "*" Or _
UCase(rngValues(i, 5)) Like "*" & temp & "*" Then
'Store columns B, F & G for displaying in the ListBox
n = n + 1
ReDim Preserve a(1 To 3, 1 To n)
a(1, n) = rngValues(i, 1)
a(2, n) = rngValues(i, 5)
a(3, n) = rngValues(i, 6)
End If
Next
'If anything found, replace the ListBox contents. Otherwise leave it as it was.
If n > 0 Then
Me.ListBox_History.Column = a
End If
thus getting rid of the code which is reading into memory all 1048576 rows of your sheet, and the need of the Transpose (which won't work on large volumes of data).
You will also need to change the False leg of your If, perhaps in a similar fashion.