What's the purpose of SetRegView lastused? - nsis

Question

What's the purpose of SetRegView lastused?
The docs only talk about the 32/64 bit registry views, which I understand.
I thought it might be acting as a stack, like this person, being able to switch back to the view before the one currently in use. But the response to someone asking that question was:
No stack. Just the last one used.
In which case, if you're already in the 32 bit view, it's just equivalent to SetRegView 32? That doesn't seem right, what am I missing?
My google-fu only got me so far, finding this example from Mozilla (snippet from full script):
; Since the Maintenance service can be installed either x86 or x64,
; always use the 64-bit registry.
${If} ${RunningX64}
; Previous versions always created the uninstall key in the 32-bit registry.
; Clean those old entries out if they still exist.
SetRegView 32
DeleteRegKey HKLM "${MaintUninstallKey}"
; Preserve the lastused value before we switch to 64.
SetRegView lastused
SetRegView 64
${EndIf}
Then in a couple places later in the script:
${If} ${RunningX64}
SetRegView lastused
${EndIf}
Looking at the context there, if you call SetRegView 32, followed by SetRegView lastused, does that mean any future uses of SetRegView lastused will always result in the 32 bit registry view?

Answer 1

Not it is not a stack (but you could argue that it should be). It is simply the last set 32/64 state.
The SetRegView instruction is transformed into a NSIS opcode called EW_SETFLAG by MakeNSIS and its implementation in a installer looks something like this:
if (get_last_used)
g_exec_flags[flag] = g_exec_flags_last_used[flag] ; Restore previous
else
g_exec_flags_last_used[flag] = g_exec_flags[flag] ; Set last used
g_exec_flags[flag] = new_value ; Assign new value
These flags are also available to plug-ins in the exec_flags_t struct.
It is only useful if you mainly deal with one registry view but once in a while need to read from the other view:
Section
SetRegView 64
ReadRegStr $0 HKLM "Software\Foo" "Bar"
SetRegView lastused ; We are now back to the default view (32-bit in this case)
SectionEnd
or if you mainly use the 64-bit view:
Function .onInit
SetRegView 64
FunctionEnd
Section
SetRegView 32
ReadRegStr $0 HKLM "Software\Foo" "Bar"
SetRegView lastused ; We are now back to the previous view (64-bit in this case)
SectionEnd
I guess it is implemented this way because it simply reuses the lastused functionality used by other flags. It also simplifies things because it never has to allocate more memory. I also don't know why it is undocumented.