Excel Vba recursive Sub not changing Variant ByRef parameter - excel

Question

I have the following Sub getting a column of numbers into a Variant array than calling a Bubble sorting function on it to sort the numbers still in the Loo variable. I expect Loo to be changed i.e. numbers in it appearing in sorted order after the sorting function has received it Byref and has done its job. Interestingly the sorting happens, as a Watch shows on Inarray in the sorting function. But Loo - despite given ByRef to a Function - is never changed.
Are variant arrays not suitable for ByRef parameter passing? Am I doing something wrong in the sorter function? The Recursion is what "kills" Inarray before it can be written back to Loo?
Option Explicit
Option Base 1
Public Loo As Variant
Public Destfile As Workbook
Private i As Integer
Sub sorter()
Set Destfile = Workbooks("SomeWB")
With Destfile.Worksheets("Somesheet").ListObjects("sometable").ListColumns("Numbers")
Loo = Application.Transpose(.DataBodyRange)
End With
BubbleSortArray (Loo)
End Sub
The Bubble sorting Function is the following:
Option Explicit
Option Base 1
Private NumberOfChanges, p As Integer
Private Store As Variant
Public Sub BubbleSortArray(ByRef Inarray As Variant)
NumberOfChanges = 0
For p = 1 To UBound(Inarray, 1) - 1
If Inarray(p) > Inarray(p + 1) Then
Store = Inarray(p + 1)
Inarray(p + 1) = Inarray(p)
Inarray(p) = Store
NumberOfChanges = NumberOfChanges + 1
End If
Next p
If NumberOfChanges <> 0 Then BubbleSortArray (Inarray)
End Sub

Answer 1

The problem you are facing is caused by the parentheses around Loo in your call. VBA is different from other languages in that if a call to a routine does not have an assignment, parenthesis are not needed and in fact cause different behaviour. So:
BubbleSortArray (Loo)
more or less tells VBA to evaluate Loo before passing it to the sorting routine.
If you would call it like this, all would be well:
BubbleSortArray Loo
See for example this little demo:
Sub foo()
Dim x As Integer
x = 1
bar (x)
MsgBox x
bar x
MsgBox x
End Sub
Sub bar(ByRef x As Integer)
x = 10
End Sub

Answer 2

I believe you are going to need to explicitly make Loo and Inarray arrays and not variants (you can make them arrays of variants...or Long, String, whatever). Also not a great idea to have global or module-level variables.
Something like this will work:
Option Explicit
Option Base 1
Sub sorter()
Dim Loo() As Variant
Dim Destfile As Workbook
Set Destfile = ThisWorkbook
With Destfile.Worksheets("QueryResult").ListObjects("Table1").ListColumns("COLUMN_NAME")
Loo = Application.Transpose(.DataBodyRange)
End With
Call BubbleSortArray(Inarray:=Loo)
Stop
End Sub
Public Sub BubbleSortArray(ByRef Inarray() As Variant)
Dim NumberOfChanges As Integer
Dim p As Integer
Dim Store As Variant
NumberOfChanges = 0
For p = 1 To UBound(Inarray, 1) - 1
If Inarray(p) > Inarray(p + 1) Then
Store = Inarray(p + 1)
Inarray(p + 1) = Inarray(p)
Inarray(p) = Store
NumberOfChanges = NumberOfChanges + 1
End If
Next p
If NumberOfChanges <> 0 Then BubbleSortArray Inarray:=Inarray
End Sub