Retrofit VBA code so it can loop through columns - excel

Question

I have been using this bit of code in my VBA tinkering for years:
Range("B2:B" & Range("A" & Rows.Count).End(xlUp).Row).Formula = _
""
Range("B2:B" & Range("A" & Rows.Count).End(xlUp).Row).Select
Selection.Copy
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
I now need to be able to take this function, and loop it through 1460 columns, but that 1460 will be variable.
My tries so far look like this:
Dim a As Interger
a = 3
Do While Cells(1, a) <> ""
Range(Range("R1Ca:RCa") & Range("A" & Rows.Count).End(xlUp).Row).Formula = _
"[super convoluted formula]"
Range(Range("R1Ca:RCa") & Range("A" & Rows.Count).End(xlUp).Row).Select
Selection.Copy
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
a = a + 1
Loop
So my focused question at this point is how do I modify the "B2:B" in my starting example into a variable that can be looped to hit all of the columns?

Answer 1

It is probably best to calculate the "last row" once, e.g.
lastRow = Cells(Rows.Count, "A").End(xlUp).Row
That then allows your current statement of
Range("B2:B" & Range("A" & Rows.Count).End(xlUp).Row).Formula =
to be replaced by the equivalent
Range("B2:B" & lastRow).Formula =
which can be re-expressed, using Cells instead of addresses, as
Range(Cells(2, "B"), Cells(lastRow, "B")).Formula =
This can then be easily converted to a formula which uses a variable for the column:
Range(Cells(2, c), Cells(lastRow, c)).Formula =
Note that the column parameter of the Cells object can be either expressed as a number (i.e. column 1, 2, 3, etc) or as a string (i.e. column "A", "B", "C", etc). Using a numeric value is useful when iterating over multiple columns. Using a string value is useful when you are just using a single, known, column - it makes the code more "readable".
Your rewritten code could therefore be:
Dim c As Long
Dim lastRow As Long
lastRow = Cells(Rows.Count, "A").End(xlUp).Row
For c = 2 To Cells(1, Columns.Count).End(xlToLeft).Column
Range(Cells(2, c), Cells(lastRow, c)).Formula = "[super convoluted formula]"
Range(Cells(2, c), Cells(lastRow, c)).Value = _
Range(Cells(2, c), Cells(lastRow, c)).Value
Next
(There is no need to do a copy/paste if you are just trying to paste values - it will be safer to just set the Value property to the Value property.)