getting from list without duplicates (Groovy) - groovy

Question

I have the following list and code
def myList = [[id:8100-04, name:AAA, code:2281],
[id:8100-05, name:BBB, code:2102],
[id:8100-06, name:CCC, code:6089],
[id:8100-07, name:CCC, code:6089],
[id:8100-08, name:CCC, code:6089]]
//list is retrived but looks something like the above
def newList = myList.findAll {
(it.get("Name").equals("AAA") ||
it.get("Name").equals("BBB") ||
it.get("Name").equals("AFBO") ||
it.get("Name").equals("CCC")) }
def filteredListData = newList.collect { getListData(it.get("Id"), it.get("Name"),
it.get("Code")) }
I want to retrieve all of my newList and if there is a duplicate then retrieve the entry with the lowest id Index.
so from myList i am looking for the result to be:
[[id:8100-04, name:AAA, code:2281],
[id:8100-05, name:BBB, code:2102],
[id:8100-06, name:CCC, code:6089]]

Answer 1

You are almost there.
def myList = [
[id:"8100-04", name:"AAA", code:2281],
[id:"8100-05", name:"BBB", code:2102],
[id:"8100-06", name:"CCC", code:6089],
[id:"8100-07", name:"CCC", code:6089],
[id:"8100-08", name:"CCC", code:6089]
]
def newList = myList.findAll {
it.name in ["AAA", "BBB", "AFBO", "CCC"]
}
def map = [:]
newList.each{
if(!map.get(it.name))
map.put(it.name, it)
}
println map*.value
Output:
[
[id:8100-04, name:AAA, code:2281],
[id:8100-05, name:BBB, code:2102],
[id:8100-06, name:CCC, code:6089]
]

Answer 2

Here is the script which addresses:
Unsorted items, note that order is changed in myList below.
OP did not mention the criteria for duplicate. This considers duplicate based on name and code
def myList = [[id:'8100-07', name:'CCC', code:6089],
[id:'8100-04', name:'AAA', code:2281],
[id:'8100-05', name:'BBB', code:2102],
[id:'8100-06', name:'CCC', code:6089],
[id:'8100-08', name:'CCC', code:6089]]
def newList = myList.findAll {
it.get("name").equals("AAA") ||
it.get("name").equals("BBB") ||
it.get("name").equals("AFBO") ||
it.get("name").equals("CCC")
}
//Sort by order id, name and code fields
def criteria = { a,b -> a.id <=> b.id ?: a.name <=> b.name ?: a.code?: b.code }
//Group by name and code ; apply sort; get the first item; apply sort on final result
def result = newList.groupBy({it.name}, {it.code}).inject([]){li, k, v-> v.collect {key, value -> li << value.sort(criteria)[0]}; li}.sort(criteria)
println result
You can quickly try online Demo

Answer 3

Here is a more "functional style" solution. We group by name, this gives a list for each name. Then we sort each of these lists and take its first element.
def myList = [[id:'8100-04', name:'AAA', code:2281],
[id:'8100-05', name:'BBB', code:2102],
[id:'8100-07', name:'CCC', code:6089],
[id:'8100-06', name:'CCC', code:6089],
[id:'8100-08', name:'CCC', code:6089]]
def newList = myList.findAll {
it.name in ["AAA", "BBB", "AFBO", "CCC"]
}
def groups = newList.groupBy {it -> it.name}
def lowestIds = groups.collect({it.value.sort{it.id}[0]})
println lowestIds
Even simpler:
newList.sort{it.id}.unique{it.name}
println newList