Batch formatting of Date in multiple datasets - excel

Question

i have extracted a number of excel spreadsheets into sas using proc import. however i now need to join the datasets together and need a uniform date format for all datasets. they are currently in character format and some are structured as '1999Q1' dates and some as '12/02/2013' dates. any help on how i can change formats for all dates in all datasets?

Answer 1

You will need to use INPUT() function to convert the strings to dates so that you can merge them. Let's make some sample datasets to simulate what you might have imported from your Excel sheets.
data have1;
date='1999Q1';
var1=1;
run;
data have2;
date='02DEC2013'd ;
format date yymmdd10.;
var2=2;
run;
Now let's get the variable names and types from those datasets.
proc contents data=work._all_ noprint out=contents; run;
We can use this metadata to write some code to convert the strings into dates.
filename code temp;
data _null_;
set contents;
where upcase(name)='DATE' and type=2;
file code ;
length dsn $41;
dsn=catx('.',libname,memname);
put 'data ' dsn ';'
/ ' set ' dsn ';'
/ ' datenum=input(date,anydtdte.);'
/ ' format datenum yymmdd10.;'
/ ' rename datenum=date date=datechar;'
/ 'run;'
;
run;
%inc code / source2 ;
Now we can merge the datasets.
data want ;
merge have1 have2;
by date;
run;