Thread - Synchronize DOS output - multithreading

Question

I have a cmd that will return values to me constantly, non-stop, and I do not know how to get those values and set it on a string to send a TMemo.
Code to get the cmd result:
function GetDosOutput(CMD: string; Dir: string = 'C:\'): string;
var
SA: TSecurityAttributes;
SI: TStartupInfo;
PI: TProcessInformation;
StdOutPipeRead, StdOutPipeWrite: THandle;
Handle, WasOK: Boolean;
Buffer: array[0..255] of AnsiChar;
BytesRead: Cardinal;
utf8: UTF8String;
begin
Result := '';
SA.nLength := SizeOf(SA);
SA.bInheritHandle := True;
SA.lpSecurityDescriptor := nil;
CreatePipe(StdOutPipeRead, StdOutPipeWrite, #SA, 0);
try
FillChar(SI, SizeOf(SI), 0);
SI.cb := SizeOf(SI);
SI.dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
SI.wShowWindow := SW_HIDE;
SI.hStdInput := GetStdHandle(STD_INPUT_HANDLE);
SI.hStdOutput := StdOutPipeWrite;
SI.hStdError := StdOutPipeWrite;
Handle := CreateProcess(nil, PChar('cmd.exe /C ' + CMD), nil, nil, True,
0, nil, pchar(Dir), SI, PI);
CloseHandle(StdOutPipeWrite);
if Handle then
try
repeat
WasOK := ReadFile(StdOutPipeRead, Buffer, 255, BytesRead, nil);
if BytesRead > 0 then begin
Buffer[BytesRead] := #0;
utf8:= Result + String(Buffer);
Result:= utf8;
end;
until not WasOK or (BytesRead = 0);
WaitForSingleObject(PI.hProcess, INFINITE);
finally
CloseHandle(PI.hThread);
CloseHandle(PI.hProcess);
end;
finally
CloseHandle(StdOutPipeRead);
end;
end;
I can not wait until the end of the thread, because as the results do not stop being updated, the thread will never finish, just need to update at runtime.
I tried to use Synchronize bad did not work. How can I proceed?
My code:
type
TThread_DOS = class(TThread)
private
FCmd: string;
FResult: string;
protected
procedure Execute; override;
public
Constructor Create(const cmd: string; Notify: TNotifyEvent);
property Result: string read FResult;
property CMD: string read FCmd;
end;
constructor TThread_DOS.Create(const cmd: string; Notify: TNotifyEvent);
begin
inherited Create(false);
FCmd:= cmd;
FreeOnTerminate:= true;
OnTerminate:= Notify;
end;
procedure TThread_DOS.Execute;
begin
inherited;
FResult:= (GetDosOutput(FCmd));
end;

Answer 1

Create a TThread Class and pass a TMemo and your parameters to it and let it do anything for you
Every time you need to show the Result, you can show it with Synchronizing
For Example :
unit ThreadUnit;
interface
Uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
VCL.StdCtrls;
type
TMyThread = class(TThread)
private
FMemo : TMemo;
FCMD : String;
FDir : String;
public
constructor Create(var ResultMemo : TMemo; CMD, Dir : String);
protected
procedure Execute; override;
end;
implementation
{ TMyThread }
constructor TMyThread.Create(var ResultMemo : TMemo; CMD, Dir : String);
begin
Inherited Create(True);
FreeOnTerminate := True;
FMemo := ResultMemo;
FCMD := CMD;
if Dir = '' then
FDir := 'C:\'
else
FDir := Dir;
end;
procedure TMyThread.Execute;
var
SA: TSecurityAttributes;
SI: TStartupInfo;
PI: TProcessInformation;
StdOutPipeRead, StdOutPipeWrite: THandle;
Handle, WasOK: Boolean;
Buffer: array[0..255] of AnsiChar;
BytesRead: Cardinal;
utf8: UTF8String;
Result : String;
begin
Result := '';
SA.nLength := SizeOf(SA);
SA.bInheritHandle := True;
SA.lpSecurityDescriptor := nil;
CreatePipe(StdOutPipeRead, StdOutPipeWrite, #SA, 0);
try
FillChar(SI, SizeOf(SI), 0);
SI.cb := SizeOf(SI);
SI.dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
SI.wShowWindow := SW_HIDE;
SI.hStdInput := GetStdHandle(STD_INPUT_HANDLE);
SI.hStdOutput := StdOutPipeWrite;
SI.hStdError := StdOutPipeWrite;
Handle := CreateProcess(nil, PChar('cmd.exe /C ' + FCMD), nil, nil, True,
0, nil, pchar(FDir), SI, PI);
CloseHandle(StdOutPipeWrite);
if Handle then
try
repeat
WasOK := ReadFile(StdOutPipeRead, Buffer, 255, BytesRead, nil);
if BytesRead > 0 then begin
Buffer[BytesRead] := #0;
utf8:= Result + String(Buffer);
Result:= utf8;
Synchronize(procedure
begin
FMemo.Lines.Add(Result);
end);
end;
until not WasOK or (BytesRead = 0);
WaitForSingleObject(PI.hProcess, INFINITE);
finally
CloseHandle(PI.hThread);
CloseHandle(PI.hProcess);
end;
finally
CloseHandle(StdOutPipeRead);
end;
end;
end.
Use this thread like this :
procedure TForm2.Button1Click(Sender: TObject);
var
MyThread : TMyThread;
begin
MyThread := TMyThread.Create(Memo1, 'PING 127.0.0.1', '');
MyThread.Start;
end;
It will show the result line by line in the memo without freezing the UI
Note that how Constructor and Synchronize works ...

Answer 2

Try https://github.com/TurboPack/DOSCommand
Example use Memo:
procedure TForm1.DosCommand1NewLine(ASender: TObject; const ANewLine: string;
AOutputType: TOutputType);
begin
case AOutputType of
otEntireLine:
Memo1.Lines.Add(ANewLine);
end;
end;
http://www.gesource.jp/weblog/?p=7483