End vba code if no value found - excel

Question

I am using this code to transfer data from one sheet to another. The code allows for the data being transferred to stay on the new sheet until deleted.
Private Sub Transfer2_Click()
Dim Work_Order1 As String, Qty1 As Integer, Frame1 As String, Qty_Frame1 As Integer
Worksheets("Work_Order").Select
if Worksheets("Work_Order").Range("C12") = "" Then Exit Sub
Work_Order1 = Range("N3")
Qty1 = Range("B3")
Frame1 = Range("C12").Value
Qty_Frame1 = Range("M12")
Worksheets("Order").Select
Worksheets("Order").Range("A4").Select
If Worksheets("Order").Range("A4").Offset(1, 0) <> "" Then
Worksheets("Order").Range("A4").End(xlDown).Select
End If
ActiveCell.Offset(1, 0).Select
ActiveCell.Value = Work_Order1
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Qty1
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Frame1
ActiveCell.Offset(0, 2).Select
ActiveCell.Value = Qty_Frame1
Private Sub Transfer2_Click()
Dim Work_Order2 As String, Qty2 As Integer, Frame2 As String, Qty_Frame2 As Integer
Worksheets("Work_Order").Select
if Worksheets("Work_Order").Range("C13") = "" Then Exit Sub
Work_Order2 = Range("N3")
Qty2 = Range("B3")
Frame2 = Range("C13").Value
Qty_Frame2 = Range("M13")
Worksheets("Order").Select
Worksheets("Order").Range("A4").Select
If Worksheets("Order").Range("A4").Offset(1, 0) <> "" Then
Worksheets("Order").Range("A4").End(xlDown).Select
End If
ActiveCell.Offset(1, 0).Select
ActiveCell.Value = Work_Order2
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Qty2
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Frame2
ActiveCell.Offset(0, 2).Select
ActiveCell.Value = Qty_Frame2
Private Sub Transfer2_Click()
Dim Work_Order3 As String, Qty3 As Integer, Frame3 As String, Qty_Frame3 As Integer
Worksheets("Work_Order").Select
if Worksheets("Work_Order").Range("C14") = "" Then Exit Sub
Work_Order1 = Range("N3")
Qty3 = Range("B3")
Frame3 = Range("C14").Value
Qty_Frame3 = Range("M14")
Worksheets("Order").Select
Worksheets("Order").Range("A4").Select
If Worksheets("Order").Range("A4").Offset(1, 0) <> "" Then
Worksheets("Order").Range("A4").End(xlDown).Select
End If
ActiveCell.Offset(1, 0).Select
ActiveCell.Value = Work_Order3
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Qty3
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Frame3
ActiveCell.Offset(0, 2).Select
ActiveCell.Value = Qty_Frame3
What I am trying to do is end this code is no value is found in the "C" Range. I have the code repeated nine times because there are nine instances where this info can be found, but not all will have values all the time. If that occurs, I want it to end the code before transferring info to the new sheet.
so far I've tried:
if Worksheets("Work_Order").Range("C12")="" Then
Exit sub
But it returns with the error Block if without end if.

Answer 1

By putting the Exit Sub on a different line to the If, you are creating a "Block If", which needs an End If:
If Worksheets("Work_Order").Range("C12")="" Then
Exit sub
End If
If you want to use a "single-line If", you should put your statements on a single line:
If Worksheets("Work_Order").Range("C12")="" Then Exit sub
Both statements work in exactly the same way, but "block Ifs" are usually easier to code when you have multiple statements to be executed within either the True or False leg of the statement.
E.g.
If a = 5 Then
b = 7
c = 10 * a - b
d = 5 + b - c
Else
b = 9
c = 20 * a - 4 * b
d = 6 + b + c
End If
is easier to read than
If a = 5 Then b = 7: c = 10 * a - b: d = 5 + b - c Else b = 9: c = 20 * a - 4 * b: d = 6 + b + c
In response to your comments, I am guessing that you don't actually want to Exit Sub when you hit a blank value, you want to instead go on to process the next range.
This could be done like this:
Private Sub Transfer2_Click()
Dim Work_Order1 As String, Qty1 As Integer, Frame1 As String, Qty_Frame1 As Integer
If Worksheets("Work_Order").Range("C12").Value <> "" Then
Worksheets("Work_Order").Select
Work_Order1 = Range("N3")
Qty1 = Range("B3")
Frame1 = Range("C12").Value
Qty_Frame1 = Range("M12")
Worksheets("Order").Select
Worksheets("Order").Range("A4").Select
If Worksheets("Order").Range("A4").Offset(1, 0) <> "" Then
Worksheets("Order").Range("A4").End(xlDown).Select
End If
ActiveCell.Offset(1, 0).Select
ActiveCell.Value = Work_Order1
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Qty1
ActiveCell.Offset(0, 1).Select
ActiveCell.Value = Frame1
ActiveCell.Offset(0, 2).Select
ActiveCell.Value = Qty_Frame1
End If
'Then repeat for the next set of cells
which can be rewritten to avoid the use of Select (which leads to so many problems) as
Private Sub Transfer2_Click()
Dim Work_Order1 As String, Qty1 As Integer, Frame1 As String, Qty_Frame1 As Integer
If Worksheets("Work_Order").Range("C12").Value <> "" Then
With Worksheets("Work_Order")
Work_Order1 = .Range("N3")
Qty1 = .Range("B3")
Frame1 = .Range("C12").Value
Qty_Frame1 = .Range("M12")
End With
With Worksheets("Order").Cells(Worksheets("Order").Rows.Count, "A").End(xlUp).Offset(1, 0).EntireRow
.Cells(1, "A").Value = Work_Order1
.Cells(1, "B").Value = Qty1
.Cells(1, "C").Value = Frame1
.Cells(1, "E").Value = Qty_Frame1
End With
End If
'Then repeat for the next set of cells
But it would be best if that was split into two subroutines to avoid a lot of repetitive code:
Private Sub Transfer2_Click()
With Worksheets("Work_Order")
Transfer2_Paste .Range("N3").Value, .Range("B3").Value, .Range("C12").Value, .Range("M12").Value
'Then repeat for the next set of cells, e.g.
'Transfer2_Paste .Range("N4").Value, .Range("B4").Value, .Range("C13").Value, .Range("M13").Value
'etc
End With
End Sub
Private Sub Transfer2_Paste(Work_Order1 As String, Qty1 As Integer, Frame1 As String, Qty_Frame1 As Integer)
If Frame1 = "" Then
Exit Sub
End If
With Worksheets("Order").Cells(Worksheets("Order").Rows.Count, "A").End(xlUp).Offset(1, 0).EntireRow
.Cells(1, "A").Value = Work_Order1
.Cells(1, "B").Value = Qty1
.Cells(1, "C").Value = Frame1
.Cells(1, "E").Value = Qty_Frame1
End With
End Sub