Loop through files in a folder and countif - excel

Question

I have this VBA code to count all values that are not zero in all excel files saved in a folder and print out the result in the worbook containing the macro. the problem I am having is that it opens the same file (the first one) over and over instead of moving to the next file.
Sub RealCount()
Dim file As String
Dim row As Integer
Dim wb As Workbook
row = 2
file = Dir("\\Daglig rapport\KPI Marknadskommunikation\FEB\*.xl??")
Do While file <> ""
Set wb = Workbooks.Open("\\Daglig rapport\KPI Marknadskommunikation\FEB\*.xl??")
Call ZeroCount
file = Dir("\\Daglig rapport\KPI Marknadskommunikation\FEB\*.xl??")
Loop
End Sub

Answer 1

Here's some suggestions to get it working:
Use a path variable to keep the folder location and make the code easier to read
Fix the Workbooks.Open so the parameter should be the actual file path (I'm kind of surprised Excel's Workbook.Open would actually work with wildcards characters like * or ?)
Check that ZeroCount doesn't call any Dir functions. If you do, then Excel may very well reset your ability to call Dir to correctly get the next file in your loop. If you find that this is happening and you must absolutely call Dir inside of this loop, then you could loop through all the Dir values first and store them into an array. Then make another loop that goes through that array which calls ZeroCount (or any code that needs to use Dir within it)
Here's an example of the first two points taken care of:
Sub RealCount()
Dim path as String
Dim file As String
Dim row As Integer
Dim wb As Workbook
path = "\\Daglig rapport\KPI Marknadskommunikation\FEB\"
row = 2
file = Dir(path & "*.xl??")
Do While file <> ""
Set wb = Workbooks.Open(path & file)
Call ZeroCount
row = row + 1 ' I assume you want to increment row each time as well maybe?
file = Dir()
Loop
End Sub
For some more examples of using VBA's Dir - see here: http://www.exceltrick.com/formulas_macros/vba-dir-function/