VBA - Excel - Parse CSV and iterate through each row - excel

Question

Sub CopyData()
Dim wb As Workbook
Dim wsDest As Worksheet
Dim sFilePath As String
Dim aData As Variant
sFilePath = Application.GetOpenFilename("CSV Files, *.csv", MultiSelect:=False)
If sFilePath = "False" Then Exit Sub 'Pressed cancel
Set wb = ActiveWorkbook
Set wsDest = wb.Sheets("Sheet2")
Application.ScreenUpdating = False
With Workbooks.Open(sFilePath)
aData = .Sheets(1).Range("A1", .Sheets(1).Cells(.Sheets(1).Rows.Count, "F").End(xlUp)).Value
.Close False
End With
Application.ScreenUpdating = True
With wsDest.Range("B11").Resize(UBound(aData, 1), UBound(aData, 2))
.Value = aData
.Resize(, 1).NumberFormat = "mm/dd/yyyy" 'Can set date format here, change to dd/mm/yyyy if needed
End With
End Sub
Above is a sample code to copy data from one workbook to another.
I want to be able to copy specific cells on specific rows that comply with an IF operator, and for that I want to be able to iterate through each row of the CSV file that is being opened to apply the logical operators.
How can the above code be modified to achieve that?
I'm not very good with VBA.

Answer 1

The simple and "standard" way is to apply an AutoFilter on the source and copy the visible range.
Sub CopyData()
Dim wsDest As Worksheet: Set wsDest = ThisWorkbook.Sheets("Sheet2")
Dim sFilePath As String: sFilePath = Application.GetOpenFilename("CSV Files, *.csv", MultiSelect:=False)
If sFilePath = "False" Then Exit Sub 'Pressed cancel
Application.ScreenUpdating = False
On Error GoTo Cleanup
With Workbooks.Open(sFilePath).Sheets(1)
With .Range("A1", .Cells(.Rows.Count, "F").End(xlUp))
.AutoFilter 1, ">" & CDate("1/1/2017") ' <-- Captures dates since year 2017 for example
.SpecialCells(xlCellTypeVisible).Copy
End With
wsDest.Range("B11").PasteSpecial
wsDest.Columns("B").NumberFormat = "mm/dd/yyyy"
.Parent.Close False
End With
Cleanup:
Application.ScreenUpdating = True
End Sub