Cannot refresh reference to external xlsm file - excel

Question

I have two Excel files, parent and child, where child contains a library of functions used by parent's functions. For versioning purposes I keep them in the same folder and copy and rename the folder in exactly the same location to keep track of my versions. I also want the references to be dynamically updated so that when i move to a new version, parent always points to child in the same location.
So in order to accomplish this I have implemented two routines in parent.
One, is in ThisWorkbook I used Workbook_Open sub:
Private Sub Workbook_Open()
'Force the location of the shared library to the current project folder irrespective where the project is located
Call reloadSharedLibrary
End Sub
Two, in Modules.Libraries I added another sub reloadSharedLibrary:
Public librName As Variant
Public isRefReloaded As Boolean
Sub reloadSharedLibrary()
isRefReloaded = True
Dim VBAEditor As VBIDE.VBE
Dim vbProj As VBIDE.VBProject
Dim chkRef As VBIDE.Reference
Dim BoolExists As Boolean
Dim librPath As String
Set VBAEditor = Application.VBE
Set vbProj = ActiveWorkbook.VBProject
librName = "lib_emtm"
librPath = Application.ActiveWorkbook.Path & "\lib.xlsm"
' delete any shared lib (if exists)
For Each chkRef In vbProj.References
If chkRef.Name = librName Then
vbProj.References.Remove chkRef
BoolExists = True
End If
Next
' you can only add it to VBAProject only after you quit the above loop
On Error Resume Next
vbProj.References.AddFromFile librPath
If Err.Number <> 0 Then
MsgBox "FATAR ERROR: Cannot find shared library file in project root": End
End If
Set vbProj = Nothing
Set VBAEditor = Nothing
End Sub
Now, the problem with this is that when I copy the project folder to a new version folder the reference to child does not get updated. The child the version uses is from the old version.
What am I doing wrong?

Answer 1

The problem is that when the VBA project loads a document and its references, it assigns them a name, which is lib_emtm in your case. When you uncheck the reference to it, the reference is removed from the VBA project but the project editor will keep the name in its cache. This name will remain in the cache until you close the workbook and reopen it.
You can verify this in the project references menu: you will see that even if you uncheck the reference, the name of the library lib_emtm will still appear there.
Then when you try to add a reference to the "other" child workbook (the one in the same folder), the editor will find that the name is lib_emtm which is the same as the one in the cache, so instead of opening the new document and parsing it, it will use the cached version, which is the old one!
If you close then re-open the application, the name of the library will disappear from the cache, so you can install the correct version. To be complete, this pattern occurs only with references to other workbooks, not with regular DLL's installed on the system.
I tried but couldn't find a VBA way to remove the Cached library from the editor's cache before re-installing it. If someone finds a way it would complete the solution. Therefore at the moment we must close the document before re-opening it and installing the lib. This process might be automated but I suggest a solution that prompts the user for that.
' Module ThisWorkbook
Option Explicit
Private Sub Workbook_Open()
'Force the location of the shared library to the current project folder irrespective where the project is located
Dim check As Boolean: check = checkSharedLibrary
If check Then Exit Sub
Dim prompt
prompt = MsgBox("The installed lib_emtm library was uninstalled because it was not the correct version." & vbCrLf & _
"If you click Ok, document will close and the correct version will be automatically installed when you reopen it." & vbCrLf & _
"If you click Cancel, library will not be available in this session but will be installed next time you open the document", vbOKCancel)
If prompt = vbOK Then ThisWorkbook.Close True
End Sub
' Regular module
Option Explicit
Private librName As String, librpath As String
' if correct version already installed (correct path) return true
' if library installed with incorrect version, uninstall it and return false
' if library not installed, install it and return true
Public Function checkSharedLibrary() As Boolean
librName = "lib_emtm"
librpath = ThisWorkbook.Path & "\lib_emtm.xlsm"
Dim chkRef As VBIDE.Reference
For Each chkRef In ThisWorkbook.VBProject.References
If chkRef.name = librName Then Exit For
Next
If chkRef Is Nothing Then
install_emtm
checkSharedLibrary = True
ElseIf Left(chkRef.FullPath, InStrRev(chkRef.FullPath, "\") - 1) = ThisWorkbook.Path Then
checkSharedLibrary = True ' we have the correct version
Else
ThisWorkbook.VBProject.References.Remove chkRef ' return false
End If
End Function
Private Sub install_emtm()
On Error Resume Next
ThisWorkbook.VBProject.References.AddFromFile(librpath)
If Err.Number <> 0 Then MsgBox "FATAR ERROR: Could not install lib_emtm:" & vbCrLf & Err.Description & vbCrLf & vbCrLf & _
"Please verify that the library's file is present in the same folder or try a manual install"
End Sub
A final remark, the process can be automated without user intervention if we close directly the application but before that we can schedule the re-opening of the workbook . But things might get complicated because the user may have other Excel documents open, so we cannot oblige her to close everything.