VBA 2010 - CDate Type Mismatch Issue - excel

Question

I have the following code that runs without issue on some laptops and then others it will error out with a Type Mismatch. In Column AA are Dates with format (mm/dd/yyyy) and Column AB has the respective Times with format (hh:mm:ss).
I am subtracting the date and time from Now(). I am unable to really troubleshoot the issue because it works fine on my laptop. For others, it errors out. CLng(CDate(Now())) has a value but the other two induce type mismatch. I've tried the two lines below and also another which concatenated the date and time, then performed CLng(CDate(.
'If CLng(CDate(Now())) - CLng(CDate(Range("AA" & i).Value)) + CLng(CDate(Range("AB" & i).Value)) >= 7 Then
If CLng(CDate(Now())) - CLng(CDate(FMT(Range("AA" & i), "mm/dd/yyyy"))) + CLng(CDate(FMT(Range("AB" & i), "hh:mm:ss"))) >= 7 Then
where FMT is a public function:
Public Function FMT$(ByVal Value, ByVal strFormat)
FMT = VBA.Format$(Value, strFormat)
End Function
I am requesting my colleague to send me a screenshot of his region date/time settings.. I was thinking this could be the case. I've read other questions similar to this but not able to figure it out. Thanks in advance.

Answer 1

If columns AA and AB contain text rather than dates and times, try using the following statement:
If Now() - (DateValue(Range("AA" & i)) + TimeValue(Range("AB" & i))) >= 7 Then
This will probably still be problematic if the users have a local date setting of, for instance, dd/mm/yyyy but your columns are storing a string representing a date in some other locale's date setting. If that is the case, you may need to parse the fields and do it as follows:
Dim myDateStr As String
Dim myTimeStr As String
Dim myDateTime As Date
myDateStr = Range("AA" & i)
myTimeStr = Range("AB" & i)
myDateTime = DateSerial(CInt(Mid(myDateStr, 7, 4)), CInt(Mid(myDateStr, 1, 2)), CInt(Mid(myDateStr, 4, 2))) + _
TimeSerial(CInt(Mid(myTimeStr, 1, 2)), CInt(Mid(myTimeStr, 4, 2)), CInt(Mid(myTimeStr, 7, 2)))
If Now() - myDateTime >= 7 Then

Answer 2

You can use the Value2 property of the Range object to get the numerical representation of a DateTime. Try:
If CDbl(Now()) - (Range("AA" & i).Value2 + Range("AB" & i).Value2) >= 7 Then
Just be sure to convert Now() to Double, otherwise it will use just the date part of the DateTime.
I find it easier to work with the numerical representation of the DateTime, as it allows you to bypass the regional settings.