Using Len(Dir) to check for picture file and insert into file - excel

Question

I am trying to insert pictures into a column F. Links for picture files are listed in column C.
I researched on-line, and found a way.
If the file is there it works, if cell in column C is left blank it leaves the corresponding cell in column F blank, but if the link contains a file name does not exist it stops.
If the filename is corrupt = stated but not existing, I want to leave the cell blank and move on to the next cell.
Sub Insertpicture()
Dim myPict As Picture
Dim curWks As Worksheet
Dim myRng As Range
Dim myCell As Range
Set curWks = Sheets(1)
curWks.Pictures.Delete
With curWks
Set myRng = .Range("c2", .Cells(.Rows.Count, "c").End(xlUp))
End With
For Each myCell In myRng.Cells
If Trim(myCell.Value) = "" Then
‘do nothing, move on
ElseIf Len(Dir(myCell.Value)) = 0 Then
’here I want to leave the cell empty and just move on to check next cell
Else
With myCell.Offset(0, 3)
Set myPict = myCell.Parent.Pictures.Insert(myCell.Value)
myPict.Top = .Top
myPict.Width = .Width
myPict.Height = .Height
myPict.Left = .Left
myPict.Placement = xlMoveAndSize
End With
End If
Next myCell
End Sub

Answer 1

If the cell is empty, Dir(myCell.Value) will be the same thing as Dir(vbNullString), which will return the next result from your last Dir command. Since Dir holds state this way, it isn't the ideal way to determine if a file (or lack of a file) exists. I'd use the Scripting.FileSystemObject instead:
'Add a reference to Microsoft Scripting Runtime
Sub Insertpicture()
Dim myPict As Picture
Dim curWks As Worksheet
Dim myRng As Range
Dim myCell As Range
Set curWks = Sheets(1)
With curWks
.Pictures.Delete
Set myRng = .Range("c2", .Cells(.Rows.Count, "c").End(xlUp))
End With
With New Scripting.FileSystemObject
For Each myCell In myRng.Cells
If IsError(myCell.Value) Then
'do nothing, move on
ElseIf Not .FileExists(myCell.Value) Then
'leave the cell empty
myCell.Value = vbNullString
Else
With myCell.Offset(0, 3)
'You need to test to see if it's an image file here.
Set myPict = myCell.Parent.Pictures.Insert(myCell.Value)
myPict.Top = .Top
myPict.Width = .Width
myPict.Height = .Height
myPict.Left = .Left
myPict.Placement = xlMoveAndSize
End With
End If
Next myCell
End With
End Sub
Note that you also need to test for errors in the cells before you use the values and you should also either add error handling or test to see if the file you found was a valid image file.