Excel: Most frequent value/word in a not-continous range - excel

Question

I need to find the most frequent word (categorical text, e.g."T2") in a row, but not across all columns. If the range was continous I would attempt something like:
=INDEX(B3;M3,MODE(MATCH(B3;M3,B3;M3,0)))
However, I'm doing this for multiple variables and don't want to make a separate subset sheet/file for each one so hope this is possible. I'm attempting to use the following formula but get an error message that hightlights the MODE function:
=INDEX((B3;F3;J3),MODE(MATCH(B3;F3;J3,B3;F3;J3,0)))
My data looks something like this:
person A person B person C
ID Var1 Var2 Var3 Var4 Var1 Var2 Var3 Var4 Var1 Var2 Var3 Var4
1 T2 C1 N f T2 C1 N f T4 C9 Y e
2 T4 C5 Y b T4 C1 Y b T2 C1 N e
3 T2 C2 N g T4 C5 Y d T2 C1 N f
4 T4 C9 Y e T4 C1 Y b T2 C1 N e
5 T1 C2 N b T2 C2 N h T2 C2 N g
6 T4 C9 Y b T4 C1 Y b T4 C9 Y f
7 V2 C1 Y c V6 C2 N c T2 C2 N h
Example
And the result I want is to add a column to the end that gives me the most common value/name, exapmle for Var1:
ID Mode_Var1
1 T2
2 T4
3 T2
4 T4
5 T2
6 T4
7 NA
Am I on the right track? Is this possible using Index, Mode and Match? Is there another way if this doesn't work? Thanks for any help!
EDIT: Added table (same as in image), made range in first example correspond to example data

Answer 1

You would use a countif in an array form of INDEX/MATCH:
=INDEX(B2:M2,MATCH(MAX(IF(MOD(COLUMN(B2:M2),4)=2,COUNTIF(B2:M2,B2:M2))),IF(MOD(COLUMN(B2:M2),4)=2,COUNTIF(B2:M2,B2:M2)),0))
Being an array formula it needs to be confirmed with Ctrl-Shift-Enter instead of Enter when exiting edit mode. If done correctly Excel will put {} around the formula.
Put this formula in N2, press Ctrl-Shift-Enter, then copy/drag down.

Answer 2

Given a setup as shown, use this array formula* in cell B13 and copy over and down:
=INDEX(INDEX($B$3:$M$9,MATCH($A13,$A$3:$A$9,),0),MODE(IFERROR(MATCH(INDEX($B$3:$M$9,MATCH($A13,$A$3:$A$9,),0),IF($B$2:$M$2=B$12,INDEX($B$3:$M$9,MATCH($A13,$A$3:$A$9,),0)),0),-COLUMN($B$3:$M$9))))
The #N/A results mean that there was no most frequent entry for that ID and Var (all three had different entries). If you want to put something else there,wrap the formula in an IFERROR.
*Array formulas must be confirmed with Ctrl+Shift+Enter instead of just Enter. When done correctly, the formula will be surrounded by curly braces {=formula}, those are added automatically so don't try to add them manually.