Applescript - Preserving Image Dimensions When Inserting Images into Excel - excel

Question

I am currently in the final stages of creating a workflow for a very tedious and drawn-out weekly process involving using data in an excel to insert images.
I have managed to work out a combination of Automator and Applescript to achieve a workflow that gets the images in the excel, in their proper place but with my current applescript, they are coming in at a set size, 100 x 100
Here is the issue:
I need all of the images to come in at a height of 100px but I need the width to be flexible. I can't seem to figure out the last piece of this which I assume would be an Applescript command for excel to lock the aspect ratio.
Here is the current applescript I am using for the actual image import:
tell application "Finder"
set imageFolder to "Macintosh HD:Users:adlife:Desktop:Temporary_Image_Hold - Copyright Filings"
end tell
tell application "Finder"
set imageList to files of folder imageFolder
end tell
tell application "Microsoft Excel"
set imageHeight to 100
set imageWidth to 100
set imageCount to count of imageList
set theRange to active cell of worksheet 1 of workbook 1
set thisStep to 0
set theLeft to left position of active cell
repeat with imageFile in imageList
set theTop to (top of active cell)
set newPic to make new picture at beginning of worksheet 1 of workbook 1 with properties {file name:(imageFile as text), height:imageHeight, width:imageWidth, top:theTop, left position:theLeft, placement:placement move}
set thisStep to thisStep + 1
end repeat
end tell
I am running Microsoft Excel 2011 on El Capitan
Any help here would be greatly appreciated!
Thanks!

Answer 1

There is no image property to force the aspect ratio. The check box in user interface is to lock the ration when user moves or resize the image.
The solution is to get image dimensions and apply the ratio (width / height) to your defined image height (=100). Dimensions are provided using the "Image Events" instructions. Then you can used the new width as the "width" property in the "make new picture".
set imageFolder to "Macintosh HD:Users:adlife:Desktop:Temporary_Image_Hold - Copyright Filings"as alias
tell application "Finder" to set imageList to files of folder imageFolder
tell application "Microsoft Excel"
set imageHeight to 100
set imageWidth to 100 -- just a default value, not really needed
set imageCount to count of imageList
set theRange to active cell of worksheet 1 of workbook 1
set thisStep to 0
set theLeft to left position of active cell
repeat with imageFile in imageList
set theTop to (top of active cell)
tell application "Image Events" -- open the image and get dimensions
set theFile to imageFile as alias
set myImage to open theFile -- don't worry, it will not open the fiel for user, only for the script !
set {W, H} to dimensions of myImage
set imageWidth to imageHeight * W / H -- set width using the proportion of image = W/H
end tell
set newPic to make new picture at beginning of worksheet 1 of workbook 1 with properties {file name:(imageFile as text), height:imageHeight, width:imageWidth, top:theTop, left position:theLeft, placement:placement move}
set thisStep to thisStep + 1
end repeat --next image to place
end tell
I tested that script (of course with my own image folder !), and it works with El Capitain and Excel 2011.
As you can see, I also changed the first lines of your code:
To Set imageFolder, you do not need to do it in a tell "Finder" block.However, it must be set as "alias".
To get all files, you can tell "Finder" in single line, without tell / end tell block. (more simple)