Looping through each workbook in folder + pressing button VBA - excel

Question

Sub LoopAllExcelFilesInFolder()
Dim wb As Workbook
Dim myPath As String
Dim myFile As String
Dim myExtension As String
Dim FldrPicker As FileDialog
'Optimize Macro Speed
Application.ScreenUpdating = False
Application.EnableEvents = False
Application.Calculation = xlCalculationManual
'Retrieve Target Folder Path From User
Set FldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
With FldrPicker
.Title = "Select A Target Folder"
.AllowMultiSelect = False
If .Show <> -1 Then GoTo NextCode
myPath = .SelectedItems(1) & "\"
End With
'In Case of Cancel
NextCode:
myPath = myPath
If myPath = "" Then GoTo ResetSettings
'Target File Extension (must include wildcard "*")
myExtension = "*.xls"
'Target Path with Ending Extention
myFile = Dir(myPath & myExtension)
'Loop through each Excel file in folder
Do While myFile <> ""
'Set variable equal to opened workbook
Set wb = Workbooks.Open(Filename:=myPath & myFile)
'Ensure Workbook has opened before moving on to next line of code
DoEvents
'Press button in sheet 51
wb.Worksheets("51").CommandButton1.Value = True
'Save and Close Workbook
'wb.Close SaveChanges:=True
'Ensure Workbook has closed before moving on to next line of code
DoEvents
'Get next file name
myFile = Dir
Loop
'Message Box when tasks are completed
MsgBox "Task Complete!"
ResetSettings:
'Reset Macro Optimization Settings
Application.EnableEvents = True
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub
I have a folder with 50 workbooks with the same worksheets in each workbook. I have 2 buttons in each of the worksheets in the workbook that allows me to download/upload to db. I need to loop through each workbook and have it press the upload button in sheet51.
wb.Worksheets("51").CommandButton1.Value = True
Can anyone look through what I'm doing wrong? I'm getting this message -- Run-time error: '438': Object doesn't support this property or method.

Answer 1

CommandButtons don't have a Value property, so I think you want to invoke the button's Click event, i.e.:
wb.Worksheets("51").CommandButton1_Click
The CommandButton1_Click event will first need to be declared Public, rather than Private, i.e.:
Public Sub CommandButton1_Click()
While it is declared Private, it can only be accessed by code within the worksheet itself.
The following edit, for which I am very grateful, was made by Comintern:
NOTE: If you don't want to manually change all of the event handler routines, you can simply change them from Private to Public by using VBA Extensibility:
'Requires a reference to Microsoft Visual Basic for Applications Extensibility
'Also requires "Trust access to the VBA project object model" to be checked.
'in Macro Security.
Dim targetLine As Long
'The "51" in VBComponents("51") is the name of the code module which is usually, but
'not always, the same as the sheet name
With wb.VBProject.VBComponents("51").CodeModule
targetLine = .ProcStartLine("CommandButton1_Click", vbext_pk_Proc)
.ReplaceLine targetLine, "Public Sub CommandButton1_Click()"
End With
wb.Sheets("51").CommandButton1_Click