Awk command to convert hex to signed decimal - linux

Question

I have a text file which consists of 3 columns with hex numbers (values are variable, these used only as an example):
X Y Z
0a0a 0b0b 0c0c
0a0a 0b0b 0c0c
0a0a 0b0b 0c0c
0a0a 0b0b 0c0c
I want to convert these numbers to signed decimal and print them in the same structure they are in, so I did:
awk '{x="0x"$1;
y="0x"$2;
z="0x"$3;
printf ("%d %d %d" x,y,z);}' input_file.txt > output_file.txt
The list that I get as an output consists only of unsigned values.

Answer 1

You can use an awk function to make a Conversion from Two's Complement:
function hex2int( hexstr, nbits )
{
max = 2 ^ nbits
med = max / 2
num = strtonum( "0x" hexstr )
return ((num < med) ? num : ( (num > med) ? num - max : -med ))
}
4bit Conversion examples:
print hex2int( "7", 4 ) # +7
print hex2int( "2", 4 ) # +2
print hex2int( "1", 4 ) # +1
print hex2int( "0", 4 ) # 0
print hex2int( "f", 4 ) # -1
print hex2int( "d", 4 ) # -3
print hex2int( "9", 4 ) # -7
print hex2int( "8", 4 ) # -8
8bit Conversion examples:
print hex2int( "7f", 8 ) # +127
print hex2int( "40", 8 ) # +64
print hex2int( "01", 8 ) # +1
print hex2int( "00", 8 ) # 0
print hex2int( "ff", 8 ) # -1
print hex2int( "40", 8 ) # -64
print hex2int( "81", 8 ) # -127
print hex2int( "80", 8 ) # -128
Putting all together using a 16bit conversion:
#!/bin/awk
function hex2int( hex )
{
num = strtonum( "0x" hex )
return ((num < med) ? num : ( (num > med) ? num - max : -med ))
}
BEGIN {
nbits = 16
max = 2 ^ nbits
med = max / 2
}
{
for( i = 1; i <= NF; i++ )
{
if( NR == 1 )
{
printf "%s%s", $i, OFS
}
else
{
printf "%d%s", hex2int($i), OFS
}
}
printf "%s", ORS
}
# eof #
Input file:
X Y Z
0a0a 0b0b 0c0c
abcd ef01 1234
ffff fafa baba
12ab abca 4321
Testing:
$ awk -f script.awk -- input.txt
Output:
X Y Z
2570 2827 3084
-21555 -4351 4660
-1 -1286 -17734
4779 -21558 17185
Reference: https://en.wikipedia.org/wiki/Two's_complement
Hope it helps!