Delete row based on one letter - excel

Question

Need help with my code.
In (Column C) I have values MG01, MG02a, MG02b, MG02c. And in (Column A) different values. Code needs to delete row if value in column A is "1" and
in Column C if it finds letters at the end of text such as b, c, d, e, ....
And with "c" code do not recognized MG02c help please.
Sub xDeleteRowz()
Last = Cells(Rows.Count, "A").End(xlUp).Row
For i = Last To 1 Step -1
If (Cells(i, "A").Value) = "1" And (Cells(i, "C").Value) = "*c*" Then
Cells(i, "A").EntireRow.Delete
End If
Next i
End Sub

Answer 1

This sounds like something more suited for a regular expression:
Sub xDeleteRowz()
Last = Cells(Rows.Count, "A").End(xlUp).Row
With CreateObject("VBScript.RegExp")
.Pattern = "MG\d{2}[a-z]"
.IgnoreCase = False
For i = Last To 1 Step -1
If (Cells(i, "A").Value) = "1" And .Test(Cells(i, "C").Value) Then
Cells(i, "A").EntireRow.Delete
End If
Next i
End With
End Sub
Note that the expression requires the value to begin with MG##. If the start of the value can be different, replace this line...
.Pattern = "MG\d{2}[a-z]"
...with...
.Pattern = ".+[a-z]"
... and it will match anything with a lowercase letter at the end. You can also limit to specific letters by changing the range inside the brackets. I.e., if it's only 'a' through 'g', it would be:
.Pattern = ".+[a-g]"

Answer 2

Change
If (Cells(i, "A").Value) = "1" And (Cells(i, "C").Value) = "*c*" Then
to
If (Cells(i, "A").Value) = "1" And (Cells(i, "C").Value) like "*c*" Then
or
If (Cells(i, "A").Value) = "1" And InStr(1, Cells(i, "C").Value, "c", vbTextCompare) Then
May I also suggest that you make some more changes to your code and start coding explicitly like so:
Option Explicit
Sub xDeleteRowz()
Dim i As Long, Last As Long
Last = Cells(Rows.Count, "A").End(xlUp).Row
With ThisWorkbook.Worksheets(1)
For i = Last To 1 Step -1
If .Cells(i, "A").Value = "1" And InStr(1, .Cells(i, "C").Value, "c", vbTextCompare) Then
.Rows(i).EntireRow.Delete
End If
Next i
End With
End Sub
Update:
Based on the latest comment a more suitable approach might be the following:
Option Explicit
Sub xDeleteRowz()
Dim i As Long, Last As Long
Last = Cells(Rows.Count, "A").End(xlUp).Row
With ThisWorkbook.Worksheets(1)
For i = Last To 1 Step -1
If .Cells(i, "A").Value = "1" Then
Select Case LCase(Right(.Cells(i, "C").Value, 1))
Case "b", "c", "d", "e", "f", "g"
.Rows(i).EntireRow.Delete
End Select
End If
Next i
End With
End Sub