Excel 2013: Label deconfliction in labeled scatter plot - excel

Question

In Excel 2013, I am labeling a scatter plot with values from cells. I'd like the labels to not overlap. I can manually move labels, but I've created a filter to automatically create new plots, so I would like the label deconfliction to happen automatically as well.
Is this possible? Bonus for solutions without VBA.
Example of overlapping labels below:

Answer 1

Here's a non-VBA solution that works if there aren't too many points and the range of values is fairly stable.
It works by splitting your Y series into two separate series, one which has labels above the points and one which has labels below the points.
By default, points will be put into the series with labels below the point. However, for each point, the splitting formula checks whether there is another nearby point that is below or level to the current point. If there is, then the current point is put into the series with labels above the point instead.
I'm assuming you have data in 3 columns: Filter, X, Y. (This also works if you're just filtering on X or Y, you can ignore the Filter column)
Four working columns are required. The first two are X Filtered and Y Filtered.
Using the example in my screenshots below, this formula goes into D2 and fills both D and E columns:
=SUBTOTAL(9,B2)
This just causes the data points to go to 0,0 if they're filtered out, so that they're ignored in the splitting formula.
To make things easier to read, set the names of the filtered values to X (D2:D10) and Y (E2:E10)
Then this formula goes into F2 as an array formula, entered using CTRL + SHIFT + ENTER, and then filled down.
=IF(SUM((ABS(D2-X)<0.75)*(E2-Y>0)*(E2-Y<0.75))+(SUM((ABS(D2-$D$2:D2)<0.75)*($E$2:E2=E2))>1),E2,NA())
This formula creates the series with labels above the point. The formula does two checks:
Checks if there are any other points that are "close" and below the current point.
Checks if there are any previous points that are "close" and level to the current point. (For this check, we can't compare to all points otherwise both points will have labels above the point. We only check up the current point so that the first point still has a label below and subsequent points have a label above.)
If either of these conditions are met, then the value is used, otherwise NA() is used (so that no point is displayed).
In this formula, close is defined as "0.75" on both the X and Y axis. You'll need to change these values in your formula based on what is "close" in your data. I.e. what difference in X and Y values requires labels to be placed on opposite sides of the points.
This formula then goes into G2 to create the series with labels below the point, which is all remaining values:
=IF(ISERROR(F2),E2,NA())
One trick is just required to make the autofilter work on the data. Because we used the SUBTOTAL formula, Excel thinks the last row is a subtotal row and automatically excludes it from the autofilter, even if we select all of the data before applying the autofilter. To use an autofilter, you'll actually need to create an extra dummy row with no subtotal functions before creating the autofilter.
Now, create the scatter plot with 2 series:
Series 1 using X and Y Above
Series 2 using X and Y Below
(No need to include a blank row in these data series)
Format both series to be the same in all details, except Series 1 has labels displayed above points and Series 2 has labels displayed below points.
My screenshots below show results, including when filtering. Labels will always be below values, unless there is another visible point nearby. Each screenshot also shows one of the formulas.
All points:
Filtered on "a"
Filtered on "b"
EDIT: We can actually make the formula a little smarter to handle multiple close level values. This will alternate each subsequent value between having a label above and below. However, it only works while all values are within the "close" range and only if the data is sorted by X first
=IF(SUM((ABS(D2-X)<0.75)*(E2-Y>0)*(E2-Y<0.75))+(MOD(SUM((ABS(D2-$D$2:D2)<0.75)*($E$2:E2=E2)),2)=0),E2,NA())