Compare 2 Cells and Find Missing Values in Excel - excel

Question

I'm currently comparing 2 databases where ZIP codes have been entered manually. I need to compare the ZIP codes for hundreds of accounts in each database to check if anything is missing. I've ordered all the values in ascending order in excel but cant seem to find a quick way to check what's missing.
Column A: Database A ZIPS (The correct ZIPs)
14464, 14515, 14612, 14615, 14626
Column B: Database B ZIPS (Manually Entered)
14464, 14612, 14615, 14626
Column C: Missing ZIPs
14515
EDIT: I should have clarified, the data is stored in this manner.. each zip is not stored in a separate column, there are multiple Zips for each agent.
Image of worksheet
I know there must be a way to find this value using an excel VBA!
Thanks

Answer 1

Answer prior to seeing author's data format
Luckily the task is not too hard. You just need to simply use:
=IF(COUNTIF(list,value),"Output if it exists","Output if missing")
So in your case using the columns you define...
=IF(COUNTIF($B:$B,$A1),"",A1)
Then apply the formula for the length of the correct zip column.
see: https://exceljet.net/formula/find-missing-values
Example picture here

Answer 2

give this a go
Public Function ShowMissingZips(rngSource As Range, _
rngMatch As Range) As String
Dim colSource As Collection
Dim colMatch As Collection
Dim colOutput As Collection
Dim varSource As Variant
Dim varMatch As Variant
Dim varOutput As Variant
Dim intCounter As Integer
Dim blnMatched As Boolean
Dim strSource As String
Dim strMatch As String
Dim strOutput As String
Set colSource = New Collection
Set colMatch = New Collection
Set colOutput = New Collection
strSource = Replace(rngSource.Value, " ", "")
For Each varSource In Split(strSource, ",")
colSource.Add varSource
Next
' Clean up source data
strMatch = Replace(rngMatch.Value, " ", "")
For Each varSource In Split(strMatch, ",")
colMatch.Add varSource
Next
' Clean up match data
For Each varSource In colSource
blnMatched = False
For Each varMatch In colMatch
If varSource = varMatch Then
blnMatched = True
Exit For
End If
Next
' Note if it's not matched
If Not blnMatched Then
colOutput.Add varSource
End If
Next
' Only output if there's anything present
If colOutput.Count > 0 Then
For Each varOutput In colOutput
strOutput = strOutput & CStr(varOutput) & ", "
Next
strOutput = Left$(strOutput, Len(strOutput) - 2)
End If
ShowMissingZips = strOutput
End Function
To use it, press Alt-F11 to get to the VBA editor. Find your workbook in the project explorer (Ctrl-R if not visible) and on the menu at the top click Insert..., Module.
Paste this code in.
Go back to your workbook and assuming that you've kept the columns as before (A, B & C and with row 2 as the first data row), go to cell C2 and type
=ShowMissingZips(A2,B2)
You should see what you're after. It's not pretty and I'd normally add error handling, but it'll do for a quick fix.
When you save it, be sure to use the XLSM format (Excel 2007+) so that the VBA is retained.