Excel Data Validation (Text Length) [closed] - excel

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 5 years ago.
Improve this question
This will probably have to be something that is done in VBA, which is fine.
Some background information: I am wanting to use the text length option in Excel's Data validation. I am needing to limit to 60 characters or less. This is the easy part, however.
My question is, if a user has exceeded this 60-character threshold, I do not want my error alert to remain static and give a generic response saying "you must keep below 60 characters..." I want it to actually count the number of characters the user attempted to place in the cell, then on the Error Alert popup I would like it to be more specific, such as: You have exceeded the 60-character limit by ## characters. Please shorten the input and try again. Anyone know of a solution?

Answer 1

I wrote something similar to the code provided by K Davis in another answer. Beyond coding style, here are major functional differences.
        •  handles multiple target columns
        •  adds address to message
        •  selects the rogue cell after notification
        •  loops backwards so that in the event of multiple rogue inputs, the user ends up at the first
        •  declaration and assignment of variables are reserved to when they are actually required
        •  critical stop message box
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Union(Columns("B"), Columns("D"))) Is Nothing Then
On Error GoTo bm_Safe_Exit
Application.EnableEvents = False
Dim mssg As String, iLimit As Long, a As Long, t As Long, trgt As Range
iLimit = 60
Set trgt = Intersect(Target, Union(Columns("B"), Columns("D")))
'loop backwards through multiples so we end up at the first rogue entry
For a = trgt.Areas.Count To 1 Step -1
For t = trgt.Areas(a).Cells.Count To 1 Step -1
If Len(trgt.Areas(a).Cells(t).Value2) > iLimit Then
mssg = "You have exceeded the " & iLimit & "-character limit by " & _
Len(trgt.Areas(a).Cells(t).Value2) - iLimit & " characters in " & _
trgt.Areas(a).Cells(t).Address(0, 0) & ". Please shorten the input and try again."
MsgBox mssg, vbCritical + vbOKOnly, "Bad Input"
trgt.Areas(a).Cells(t).ClearContents: trgt.Areas(a).Cells(t).Select
End If
Next t
Next a
Set trgt = Nothing
End If
bm_Safe_Exit:
Application.EnableEvents = True
End Sub
You might want to split the sentences with one or two vbLF. To my eye, it makes the alert message more effective; particularly so with the cell address added.
I had thought about putting all of the rogue input cell addresses into a single message but that would preclude the specific overdrawn character count.
Sample text courtesy of Lorem Ipsum Generator

Answer 2

Thanks to a suggestion made by Jeepeed, I performed an internet search and stumbled upon this site. I have modified this person's code a bit to accomplish what I needed in my original question, and would like to share it in the event anyone else comes across my same issue.
Here is the code:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rng As Range
Dim rCell As Range
Dim iChars As Integer
On Error GoTo ErrHandler
'Change these as desired
iChars = 60
Set rng = Me.Range("B:B")
If Not Intersect(Target, rng) Is Nothing Then
Application.EnableEvents = False
For Each rCell In Intersect(Target, rng)
If Len(rCell.value) > iChars Then
MsgBox "You have exceeded the 60-character" & _
" limit by " & Len(rCell.value) - iChars & _
" characters." & vbCrLf & "Please shorten" & _
" your input and try again.", vbRetryCancel
End If
Next
End If
ExitHandler:
Application.EnableEvents = True
Set rCell = Nothing
Set rng = Nothing
Exit Sub
ErrHandler:
MsgBox Err.Description
Resume ExitHandler
End Sub

Answer 3

I think that would be better with an Excel formula next to the cell:
= IF( LEN( B2 ) > 60, "You have exceeded the 60-character limit by "
& ( LEN( B2 ) - 60 ) & " characters. Please shorten your input and try again.", "" )