if / then formula over many rows - excel

Question

I am trying to produce a code (simple for some) but I am inexperienced and would appreciate help.
Code to look at cell ("J1") and doing an if / then for a result in ("K1"), but I want to have this duplicated to look at the range J2 to J10 cells , to give the result in the range K2 to K10 cells as well.
The code below works for single row formula:
Sub Check()
Dim DDDD As Date, result As String
DDDD = Range("j1").Value
If DDDD >= Date Then
result = "Future"
Else
result = "Now"
End If
Range("k1").Value = result
End Sub

Answer 1

You can use a For Each loop and the Offset method, like this:
Sub Check()
Dim DDDD As Date, result As String
Dim cell as Range
For Each cell in Range("J1:J10")
DDDD = cell.Value
If DDDD >= Date Then
result = "Future"
Else
result = "Now"
End If
' Change value at the right side of the cell
cell.Offset(0,1).Value = result
Next cell
End Sub
But using VBA for this is really overkill. You could just put this formula in K1:
=IF(J1 >= TODAY(), "Future", "Now")
... and then copy/drag that formula down to the other cells below it.

Answer 2

Here is a piece of code that loops through Column J, and the result will be placed at Column K.
Sub Check()
Dim DDDD As Date
Dim result As String
Dim row, NumofRows As Integer
' use NumfofRows as a Dynamic value to decide how many rows of data you want to look at column J
NumofRows = 10
For row = 1 To NumofRows
If Cells(row, 10) >= Date Then
result = "Future"
Else
result = "Now"
End If
Cells(row, 11).Value = result
Next
End Sub

Answer 3

In the future, take a look at the rules of etiquette that make your questions both fun and enticing to answer. For your question, it will be more efficient to deal with Ranges rather than individual cells with dates in them. The For Each...Next loop can cycle through each cell in the range. Then, an If...Then...Else...End If loop can make a decision given various conditions. The Offset(0, 1) method can be used inside the If...Then loop to place results in the column to the right. The following code does what you seem to be asking:
Sub Check()
' Declare your variables
Dim MyDates As Range
Dim result As String
' First, grab all the values in the J2:JX column, where
' X can be any number of dates you choose. Note that
' you must "Set" Object variables, but you must "Dim"
' other types of variables.
Set MyDates = Range(Range("J2"), Range("J2").End(xlDown))
' Loop through every cell in the dates column and give the
' offset column (column K) a string value if the condition
' is met.
Dim Cell As Range
For Each Cell In MyDates
If Cell >= Date Then
result = "Future"
Cell.Offset(0, 1).Value = result
Else
result = "Now (or past)"
Cell.Offset(0, 1).Value = result
End If
Next Cell
End Sub
The End(xlDown) method emulates selecting a cell and pressing Ctrl+Down arrow. Also, note that this code does not handle mistakes at all. For example if you accidentally enter a date as text, the procedure will produce an incorrect result. Also, depending on the time you enter data, you could get confusing results. I've attached an image of the results in Excel here: