Identify max date in complex excel field using formula - excel

Question

I have a excel file with one column as project assignments. A sample value of this column is given below :
XXX E(10aug15-30sep16),YYY G(30nov15-29jul16),ZZZZ C(18jan16-23dec16),AAA B(04jan16-28jul16)
You can see, each assignment has start date and end date. The end date can be identified using ')' bracket, i.e. 7 character before ')' bracket.
I have to write a formula to give me max of all end dates identified. I know, I can use Macros, but due to security issues, our organization wants to avoid macros.
The output of above field should be 23-Dec-2016.
Please suggest.

Answer 1

Assuming that, for a given string (in A1):
1) The format of each end date within that string is precisely ddmmmyy
2) The entry immediately preceding each closing parenthesis is never anything other than an end date
then, array formula**:
=MAX(0+MID(A1,MODE.MULT(IF(MID(A1,ROW(INDEX(A:A,1):INDEX(A:A,LEN(A1))),1)={")",")"},ROW(INDEX(A:A,1):INDEX(A:A,LEN(A1)))))-7,7))
Format the cell containing this formula as you wish, e.g. to Custom type ddmmmyy.
Note that this solution may require a small amendment if you are using an Excel version for which the row- and column- separator in array constants are not, respectively, the semicolon and comma.
Regards
**Array formulas are not entered in the same way as 'standard' formulas. Instead of pressing just ENTER, you first hold down CTRL and SHIFT, and only then press ENTER. If you've done it correctly, you'll notice Excel puts curly brackets {} around the formula (though do not attempt to manually insert these yourself).

Answer 2

Assuming your start date is always greater than your end date, you simply need the greatest date, Which you can find using the following formula:
For a string like this in cell A1
XXX E(10aug15-30sep16),YYY G(30nov15-29jul16),ZZZZ C(18jan16-23dec16),AAA B(04jan16-28jul16)
Use the formula:
=MAX(IFERROR(VALUE(MID(A1,ROW($A$1:$A$1000),7)),0))
Enter it as an array formula - using Ctrl+Shift+Enter
Notice the following piece of code:
ROW($A$1:$A$1000)
This sets the max string length to be 1000 - make this more or less depending on what you think you'll need. The less the better as excel won't need to work as hard. I would suggest 200 might be more than enough based on your example string.

Answer 3

Not very flexible but it works so long as you have 4 end dates without departing from the given format. Can't think of any other way to do it apart from VBA which would be ideal.
=TEXT(MAX(MID(A1,FIND("-",A1,1)+1,7),MID(A1,FIND("-",A1,FIND("-",A1,1)+1)+1,7),MID(A1,FIND("-",A1,FIND("-",A1,FIND("-",A1,1)+1)+1)+1,7),MID(A1,FIND("-",A1,FIND("-",A1,FIND("-",A1,FIND("-",A1,1)+1)+1)+1)+1,7)),"ddmmmyy")

Answer 4

Use MID to extract data between the brackets. Suppose your data is in A column, you can use formula:
=MID(A2,FIND("(",A2)+1,FIND(")",A2)-FIND("(",A2)-1)
You'll get your hyphen-separated start and end dates (like this: 10aug15-30sep16).
Now use LEFT, RIGHT and SEARCH to fetch you start and end dates:
Start Date:
=LEFT(B2,SEARCH("-",B2)-1)
End Date:
=RIGHT(B2,LEN(B2)-SEARCH("-",B2))
To Convert these dates as text, use TEXT as follows:
=TEXT(D2,"ddmmmyy")
Hope I have included all the formulae you may need for your report.