Cell Formatting - excel

Question

Short question regarding excel formatting.
I am currently working on a userform-based protocol tool. The userform basically consists of two input windows, one which loads the exisitng bullet points and one to add new points.
Additionally, I would like to have the date in bold font added to each bullet point. I implemented that by searching for the position in the string where the date occurs (via instrrev) and then changing the font for the next 10 characters to bold font.
Now it works perfectly fine when creating a new bullet point, but it always messes up when I add an additional point to an existing topic or when I change an old bullet point (Then the whole text is bold). Anyone knows why this happens?
Private Sub Fertig_Click()
Dim neu As String
Dim i As Integer
neu = Date & ": " & mitschrieb_neu.Value
'No Changes
If mitschrieb_neu.Value = "" And mitschrieb_alt.Value = ActiveCell.Value Then
Unload Me
Exit Sub
End If
'First bullet point
If mitschrieb_neu.Value <> "" And ActiveCell.Value = "" Then
ActiveCell.Value = neu
i = InStrRev(ActiveCell.Value, Date)
ActiveCell.Characters(i, 10).Font.Bold = True
Unload Me
Exit Sub
End If
'New bullet point
If mitschrieb_neu.Value <> "" And ActiveCell.Value <> "" Then
ActiveCell.Value = ActiveCell.Value & Chr(10) & neu
i = InStrRev(ActiveCell.Value, Date)
ActiveCell.Characters(i, 10).Font.Bold = True
Unload Me
Exit Sub
End If
'Changed an old bullet point
If mitschrieb_neu.Value = "" And mitschrieb_alt.Value <> ActiveCell.Value Then
ActiveCell.Value = mitschrieb_alt.Value
Unload Me
Exit Sub
End If
End Sub

Answer 1

Once you execute this:
ActiveCell.Value = ActiveCell.Value & Chr(10) & neu
The Bold setting for the cell becomes uniform -- it erases any knowledge of substring formatting.
So the solution is to parse the complete value in a loop, and identify all the dates and make them bold.
At the same time I would suggest some way to reduce the duplication of code and merge all different cases (first bullet, not first bullet, modification only) into one generic way:
Private Sub Fertig_Click()
Dim neu As String
Dim i As Integer
'No Changes
If mitschrieb_neu.Value = "" And mitschrieb_alt.Value = ActiveCell.Value Then
Unload Me
Exit Sub
End If
' Join the old value with the new value and put a linefeed
' in between only if both are not empty.
' Also insert the date before the new value, if it is not empty
ActiveCell.Value = mitschrieb_alt.Value _
& IIf(mitschrieb_alt.Value <> "" And mitschrieb_neu.Value <> "", Chr(10), "") _
& IIf(mitschrieb_neu.Value <> "", Date & ": " & mitschrieb_neu.Value, "")
ActiveCell.Font.Bold = False ' start with removing all bold
' Search for all colons and put prededing date in bold (if it is a date)
i = InStr(ActiveCell.Value, ": ")
Do While i
' Make sure to only put in bold when it is a date, otherwise skip this ":"
If i > 10 And IsDate(Mid(ActiveCell.Value, i - 10, 10)) Then
ActiveCell.Characters(i - 10, 10).Font.Bold = True
End If
' find next
i = InStr(i + 1, ActiveCell.Value, ": ")
Loop
Unload Me
End Sub