excel: index match - list top 10 jobs by spend? - excel

Question

I have a list of clients on sheet1 in a spreadsheet like so:
Date Entity Sector Client Spend
April 2016 Group1 Aerospace Client A £2,000,000.00
April 2016 Group1 Aerospace Client B £5,000,000.00
April 2016 Group2 Rail Client C £13,000.00
April 2016 Group1 Aerospace Client D £45,000.00
April 2016 Group1 Telecoms Client E £20,000.00
I want to pull through a list of the top 10 clients we spend with.
I have certain parameters / criteria i need to set, i.e.
The Client must have a 'Group1' entity and must come under the 'aerospace' sector.
In Cell A10 i place my sector = Aerosapce
In cell C6 i allocate my group = Group1
So far i am using this array formula and dragging it down 10 rows, to produce 10 unique results.
=IFERROR(INDEX('Opp Data'!$H2:$H5000,MATCH(1,('Opp Data'!$G$2:$G$5000&'Opp Data'!$F$2:$F$5000=$A$10&$C$6)*('Opp Data'!$K$2:$K$5000=LARGE(IF('Opp Data'!$G$2:$G$5000&'Opp Data'!$F$2:$F$5000=$A$10&$C$6,'Opp Data'!$K$2:$K$5000),ROW(1:1))*(COUNTIF($C$13:$C13,'Opp Data'!$H$2:$H$5000)=0)),0)),"")
This should give me the clients in order with the biggest to lowest spend, producing a result like so:
Client Sector Spend
Client B
Client A
Client D
etc
etc.
Next to the client name i want to list the relevant sector that client belongs to, i.e. "Aerospace" and the spend in the column next to that.
I am doing this by using index match:
=IFERROR(INDEX('Opp Data'!$C:$C, MATCH(A2,'Opp Data'!$D:$D, 0)),"")
At the moment the data is all over the place and spends are not corresponding with the client name, and some clients are being shown that are not in group 1 or aerospace.
I am getting this:
Client Sector Spend
Client B Rail £20,000.00
Client A Aerospace £13,000.00
Client D Telecoms £2,000,000.00
etc
etc.
But i should be getting this:
Client Sector Spend
Client B Aerospace £5,000,000.00
Client A Aerospace £2,000,000.00
Client D Aerospace £45,000.00
etc
etc.
Please can someone show me where i am going wrong and let me know if there is a better way to do this?
Thanks in advance

Answer 1

To get your table the best way would be a Pivot Table with filters. This will allow you to do what you want.
Outside of that IF you want the formulas then:
First get the top Spend. To do this we need to use the LARGE() or AGGREGATE() function:
=IFERROR(AGGREGATE(14,6,$E$2:$E$6/(($C$2:$C$6=$G$2)*($B$2:$B$6=$H$2)),ROW(1:1)),"")
Put this in the first cell of your Spend column and drag down. The Row(1:1) acts as a counter that increases as it gets dragged down. That way it find the first largest then the second and so forth.
The part below / dictates that only those that meet the criteria get used. I put Aerospace in G2 and Group1 in H2.
Then we can use another AGGREGATE() function in side an INDEX to get the other data on the other two columns:
Sector:
=IF(L2<>"",INDEX($C$2:$C$6,AGGREGATE(15,6,(ROW($C$2:$C$6)-1)/(($E$2:$E$6=L2)*($B$2:$B$6=$H$2)),COUNTIF($L$2:$L2,L2))),"")
Or, since we have the desired Sector already in a cell we could simply:
=IF(L2<>"",$G$2,"")
Client:
=IF(L2<>"",INDEX($D$2:$D$6,AGGREGATE(15,6,(ROW($D$2:$D$6)-1)/(($E$2:$E$6=L2)*($B$2:$B$6=$H$2)),COUNTIF($L$2:$L2,L2))),"")
We use the AGGREGATE again instead of MATCH in case there are ties with the amount in Spend. The COUNTIF() allows us to get those duplicates where Match would only return the first one for both.
When editing the ranges on the formulas to match yours pay attention to this part: (ROW($D$2:$D$6)-1) This again is a counter that returns an integer back to the INDEX() function. We need it to start at 1. So if your data starts in Row three we would need to change the 1 to 2. It should be 1 less than the starting row.
Along with Pivot Tables, look into Advanced Filter and VBA. See HERE to see how they might help with your problem.