I want to add 10 every 9th row in Column A. It should look like the image below. Can I get some quick help please.
Thanks in Advance
~T
Put this formula in cell A1 and fill down
=FLOOR.MATH(ROW()/9)*10+1
this version is more versatile:
=FLOOR.MATH((ROW()-5+1)/9)*10+3
5 is the starting row (so start the formula in the 5th row) and 3 is the startingnumber. Adjust these values as needed.
In A1 enter 1 and in A2 enter:
=IF(MOD(ROW(),8)-1=0,A1+10,A1)
and copy down:
This approach allows the ability to put the arbitrary starting value in A1 and the increment and repeat factor in the formula.
Related
I have a workbook with Columns A1:A9 - I1:I9 containing numbers. Column J1-J9 shows the values of A1-I1. What I would like to do is show the sum of A1:A9 in J1 and follow that method down. Here is my offset formula:
=OFFSET($A$1:1,0,ROW(A1)-1,1,1)
Is there a way to add a SUM to this?
Best I can understand, you want to sum A1:A9 in J1 and B1:B9 in J2 and so on...
If that is correct, put this in J1:
=SUM(INDEX($A$1:$I$9,0,ROW(A1)))
and drag down.
Note if there is no data below then one can use:
=SUM(INDEX(A:I,0,ROW(A1)))
Scott is correct, here is another way:
=SUM(INDIRECT(ADDRESS(1,ROW())):INDIRECT(ADDRESS(9,ROW())))
Copy and paste down the column.
I have an Hlookup formula and was trying to copy it down but the position number doesn't change. I Would like to be able to copy it down to other cells and need the position to change by 1 for each cell.
Hlookup(A1,B1:D20,2,False)
When I copy the formula down , I need 2 to become 3. Any help is appreciated. Thanks!
The easiest why to do that is to have a column with the return position you want. So:
Hlookup(A1,B1:D20,zz1,False)
cell zz1 has: 2
cell zz2 has: 3
etc...
If you don't like that you can add 2 plus row() and maybe subtract to get where you want when you copy.
Perhaps add another column to refer to as this number? Then, have this column increment by one either by formula or using Excel to do it for you. Thus, if your formula was in cell A2:
// in cell
E1: 2
// in cell (and copied down)
E2: =E1+1
Then, in the cell you mentioned, the formula would become something like:
=hlookup(A1,B1:D20,E1,False)
I have number from 1 to 100 in column A1 to A100.
I am trying to achieve two results from data.
I want separately 1,2,3,4,5,6,7,8,9 and another one 10,20,30,40,50,60,70,80,90,100
Please help me
Maybe, in B1:
=1*(LEN(A1)=1)+2*(RIGHT(A1)="0")
double-click the fill handle and sort A:B on ColumnB.
This question is a bit vague. If you are looking to count by 10s, try adding a 10 in cell B1 and then adding the formula =B1+10 in cell B2. You can drag that formula down to count by 10s.
Let's say we want in column B "0, 1,2,3,4,5,6,7,8,9" and in column C "0, 10,20,30,40,50,60,70,80,90,100", put:
- =MOD(A1,10) as formula for the cell B1
- =INT(A1/10)*10 as formula for the cell C1
and then copy them to rest of the rows.
how to drag to increment the excel sheet from different file?
eg,
Cell A1 =+'[filename]59'!J6
Cell B1 =+'[filename]60'!J6
Cell C1 =+'[filename]61'!J6
i tried this now
=INDIRECT("SHEET"&COLUMN()-1&"!J6")
and readjust all the name etc, and now i wanna drag down and increment the cell to J7,J8,J9 etc
how do i do it?
Help please
Try =INDIRECT("SHEET"&COLUMN()-1&"!J"&ROW()). ROW() returns your current row. So, if you write =ROW() in A15, you'll get 15. Good for dragging down :)
If you want to change the value so that it matches a row different from your current row, you'll need to add or subtract from ROW(). So, if you wanted to put this in some cell B2 or C2 and have it match up to J5, you'd have to add 3. That would work like this:
=INDIRECT("SHEET"&COLUMN()-1&"!J"&(ROW()+3))
Obviously, you should change the 3 to whatever adjustment value you need.
I have this excel sheet that need to be adjusted. I have this STOCK Quantity column (STOCK Qty) and I need it's column to be linked to the AZ column on sheet1. And it just not linked directly, but i need to plus 9 to get it linked to the exact column.
Here to explain it further. First i need to add this formula into the "STOCK Qty" column D2 : =SUM(Sheet1!AZ1) :
But then on the column after that, say column D3, D4 and so on, i need to add 9 to each column. So column D3 will have the formula of =SUM(Sheet1!AZ10) and D4 will have the formula of =SUM(Sheet1!AZ19) and so on :
So, i hope that you could understand my question. Thanks in advance! :)
You can use INDEX function with ROWS to increment by 9 each row - try this formula in D2 copied down
=INDEX(Sheet1!AZ:AZ,9*(ROWS(D$2:D2)-1)+1)
Note you probably don't need SUM, either with this formula or yours because its only a single value
I will use the offset function, instead
=SUM(OFFSET(Sheet1!$AZ$1,(ROW()-2)*9,0))
In addition, if you are not summing anything, just
=OFFSET(Sheet1!$AZ$1,(ROW()-2)*9,0)