A multi-threaded echo server - multithreading

Question

Which "thread" does this error relate to?
thufir#tleilax:~/wunderground$
thufir#tleilax:~/wunderground$ tclsh 21.12.tcl
can't read "thread": no such variable
while executing
"thread::send -async $thread {
thread::attach $sock
fconfigure $sock -buffering line -blocking 0
fileevent $sock readable [list ReadLine $sock]
SendMes..."
(file "21.12.tcl" line 71)
thufir#tleilax:~/wunderground$
example code 21-12:
package require Tcl 8.4
package require Thread 2.5
set sock 12345
set host 127.0.0.1
#set port 7777
if {$argc > 0} {
set port [lindex $argv 0]
} else {
set port 9001
}
socket -server _ClientConnect $port
proc _ClientConnect {sock host port} {
}
#Tcl holds a reference to the client socket during
#this callback, so we can't transfer the channel to our
#worker thread immediately. Instead, we'll schedule an
#after event to create the worker thread and transfer
#the channel once we've re-entered the event loop.
after 0 [list ClientConnect $sock $host $port]
proc ClientConnect {sock host port} {
#Create a separate thread to manage this client. The
#thread initialization script defines all of the client
#communication procedures and puts the thread in its
#event loop.
set thread [thread::create {
proc ReadLine {sock} {
if {[catch {gets $sock line} len] || [eof $sock]} {
catch {close $sock}
thread::release
} elseif {$len >= 0} {
EchoLine $sock $line
}
}
proc EchoLine {sock line} {
if {[string equal -nocase $line quit]} {
SendMessage $sock \
"Closing connection to Echo server"
catch {close $sock}
thread::release
} else {
SendMessage $sock $line
}
}
proc SendMessage {sock msg} {
if {[catch {puts $sock $msg} error]} {
puts stderr "Error writing to socket: $error"
catch {close $sock}
thread::release
}
}
# Enter the event loop
thread::wait
}]
#Release the channel from the main thread. We use
#thread::detach/thread::attach in this case to prevent
#blocking thread::transfer and synchronous thread::send
#commands from blocking our listening socket thread.
# Copy the value of the socket ID into the
# client's thread
thread::send -async $thread [list set sock $sock]
# Attach the communication socket to the client-servicing
# thread, and finish the socket setup.
}
thread::send -async $thread {
thread::attach $sock
fconfigure $sock -buffering line -blocking 0
fileevent $sock readable [list ReadLine $sock]
SendMessage $sock "Connected to Echo server"
}
vwait forever
from:
This Chapter is from Practical Programming in Tcl and Tk, 4th Ed.
Copyright 2003 © Brent Welch, Ken Jones
http://www.beedub.com/book/
I had to add the sock and and host variables which makes me think that I'm missing more. The name "thread" for a thread variable seems questionable (?).

Answer 1

You've managed to chew the ordering of the lines in the book just enough to make the code really not work. If we look at the relevant chapter, we see that the code actually says this things like this:
proc _ClientConnect {sock host port} {
# Tcl holds a reference to the client socket during
# this callback, so we can't transfer the channel to our
# worker thread immediately. Instead, we'll schedule an
# after event to create the worker thread and transfer
# the channel once we've re-entered the event loop.
after 0 [list ClientConnect $sock $host $port]
}
That's much less strange! Similarly, you've moved this block:
thread::send -async $thread {
thread::attach $sock
fconfigure $sock -buffering line -blocking 0
fileevent $sock readable [list ReadLine $sock]
SendMessage $sock "Connected to Echo server"
}
outside the ClientConnect procedure, despite it needing to run inside there because that's where the thread variable is defined. (This is why you are getting that error message, BTW.) If you fix these things (and check whether you've done other silly mistakes in the same vein), the code should work.
If you're going to copy examples from elsewhere, please copy them correctly. Randomly changing the context in which code fragments run is likely to not work well in any programming language…

Answer 2

There's something odd about copy/paste from at least this PDF, it literally puts lines in the wrong order. I ran it through an online PDF to text converter with the same result.
Badly indented code to follow (sans comments, which don't copy well):
package require Tcl 8.4
package require Thread 2.5
if {$argc > 0} {
set port [lindex $argv 0]
} else {
set port 9001
}
socket -server _ClientConnect $port
proc _ClientConnect {sock host port} {
after 0 [list ClientConnect $sock $host $port]
}
proc ClientConnect {sock host port} {
set thread [thread::create {
proc ReadLine {sock} {
if {[catch {gets $sock line} len] || [eof $sock]} {
catch {close $sock}
thread::release
} elseif {$len >= 0} {
EchoLine $sock $line
}
}
proc EchoLine {sock line} {
if {[string equal -nocase $line quit]} {
SendMessage $sock \
"Closing connection to Echo server"
catch {close $sock}
thread::release
} else {
SendMessage $sock $line
}
}
proc SendMessage {sock msg} {
if {[catch {puts $sock $msg} error]} {
puts stderr "Error writing to socket: $error"
catch {close $sock}
thread::release
}
}
thread::wait
}]
thread::detach $sock
thread::send -async $thread [list set sock $sock]
thread::send -async $thread {
thread::attach $sock
fconfigure $sock -buffering line -blocking 0
fileevent $sock readable [list ReadLine $sock]
SendMessage $sock "Connected to Echo server"
}
}
vwait forever
Too bad komodo doesn't auto-indent. Anyhow, it seems to at least run without error. Looking into naglfar capabilities.