I currently have a spreadsheet with the following format
A1 = <Name>
B1 = <Email>
C1 = New-MailContact
D1 = '-Name
E1 = '-ExternalEmailAddress
F1 = =(C1&" "&D1&" ""&A1&"" "&E1&" ""&B1&""")
My issue is that my F1 column results in the following output:
New-MailContact -Name "&A1&" -ExternalEmailAddress "&B1&"
Can someone please help me to fix the A1 and B1 records so they show up as the actual name and email rather than A1 and B1?
You have a bunch of extra quotes
=C1 & " " & D1 & " " & A1 & " " & E1 & " " & B1
should display the data concatenated.
If you want the name or other fields to be quoted, for every quote you want add two quotes in the string:
= """" & C1 & """"
will display New-MailContact in quotes, like this "New-MailContact"
See this as " "" " where the outside quotes are to denote it as a string, and the two quotes inside are for displaying the one "
So if you need name and email (A1 and B1) quoted, you need
=C1 & " " & D1 & " """ & A1 & """ " & E1 & " """ & B1 & """"
More examples.
The ASCII code for a double-quote character is 22 hex or 34 dec. The ASCII character code for a space is 20 hex or 32 dec.
=C1&CHAR(32)&D1&CHAR(32)&CHAR(34)&A1&CHAR(34)&CHAR(32)&E1&CHAR(32)&CHAR(34)&B1&CHAR(34)
'alternate with CONCATENATE
=CONCATENATE(C1, CHAR(32), D1, CHAR(32), CHAR(34), A1, CHAR(34), CHAR(32), E1, CHAR(32), CHAR(34), B1, CHAR(34))
'alternate with Office 365's TEXTJOIN¹
=TEXTJOIN(CHAR(32), FALSE, C1, D1, CHAR(34)&A1&CHAR(34), E1, CHAR(34)&B1&CHAR(34))
¹ The TEXTJOIN function was introduced with Excel 2016 with Office 365 or Excel Online.
Related
I have the following sample data,
I want to concatenate string1 and string2 to produce the concatenation result
"a" "b"
using the concatenate function
I did not find any the answer in official microsoft excel documentation
https://support.office.com/en-us/article/CONCATENATE-function-8f8ae884-2ca8-4f7a-b093-75d702bea31d
How would I do this in excel? Concatenate " quotation marks
I know it's not the prettiest solution but:
=CONCATENATE(CHAR(34) & A1 & CHAR(34), " " & CHAR(34) & B1 & CHAR(34))
or
=CONCATENATE(CHAR(34), A1, CHAR(34), " ", CHAR(34), B1, CHAR(34))
CHAR(34) can be used in place of ".
Edit:
If you prefer, CHAR(34) can be replaced with """", four double quote marks - for the same effect.
I am trying to string together text from cells across by row when some of the cells are blank. I also want to have commas separating the text from each cell but cannot figure out how to only have commas put in when there is data in a cell.
I have tried using variations of concatenate and stringing the text using A1&B1&C1 but nothing is returning the data in the format I want.
Is there a combination of nested formulas I can use that will return the data in the format I want?
Here's a VBA solution I had before the newer versions:
Public Function JOINCELLS(ByVal ref As Range) As String
Dim c As Range
For Each c In ref
If Len(c) > 0 Then
JOINCELLS = JOINCELLS & c & ", "
End If
Next
JOINCELLS = Left(JOINCELLS, Len(JOINCELLS) - 2)
End Function
Then, it's just =JOINCELLS(A1:D1).
The formula below could do the trick. Concatenate the val The trim would remove spaces from the ends, and the substitute would swap the space for the comma(space).
=SUBSTITUTE(TRIM(A1 & " " & B1 & " " & C1 & " " & D1), " ", ", ")
Edit from the comments below - you could update the spaces between the quotes to be any character that does not appear in your cells. You would just have to the substitute formula to match. If you don't use the | character for example:
=SUBSTITUTE(TRIM(A1 & "|" & B1 & "|" & C1 & "|" & D1), "|", ", ")
This is what I am needing to put into Column A
= B1 & " " & C1 & " " & D1 & " " & E1 & " " & F1 & " " & G1 & " " & H1 & " " & I1
wherein the numbers will correspond to the current row that it is pasted in. Is there a faster way than simply pasting it in and manually changing the 1's to 2's, or to 3's or to 37892's?
You would string together a bunch of formulas:
=INDEX(B:B,Row()) & " " & INDEX(C:C,Row()) & ...
But if all you want is to put the formula in J1 and copy it down, then use your original formula. Put it in J1. then do one of the following:
Click on the lower right corner and drag down as far as you want.
Highlight J1 and all the cells below in which you want the formula. Go to Fill --> Down
Either of these will automatically change the row number on your original formula.
I have the following data where A to C are the columns:
A B C
-5.274 -20.63 9.251
where each number is in a different cell.
I want to combine these numbers in the following way and paste them into a new cell (those of column D)
-5.274 (-20.63 − 9.251)
How can I do this?
You can't copy and paste them like that, but you can very easily:
D2: =A2 & " (" & B2 & " - " & C2 & ")"
To keep the formatting:
=TEXT(A1;"0.00")& "(" & TEXT(B1;"0.00") & " " & TEXT(C1;"0.00") & ")"
How to return formula of other cell (column L) if choose item in column A.
Example:
if answer, then return =I5 & " " & J5
if foo, then return '=I7 & " " & J7 & " " & K7 & " x " & L7
I want to return the formula instead of the result.
Put this function in a public module
Function GetFormula(rng As Range) As Variant
GetFormula = rng.Formula
End Function
I think this is what you want. There are several options for how you want that formula returned such as R1C1 style.
Edit
Oh I think I get what you want more. Ok to apply the formula you have in your blue table to whatever cell you want in column F you can call the Indirect function.
So for example if you want to apply the formula '=I7 & " " & J7 & " " & K7 & " x " & L7 to your column F then call =INDIRECT(I7 & " " & J7 & " " & K7 & " x " & L7). In your column I don't include the = sign. it will make it a bit easier.
You can use Vlookup to find where this should be applied by using your lookup item in column A in your reference table (the blue table). Return the formula in column I.
You can achieve this by nesting your formulas.
put this in E5
=IF(A5 = "answer", A5 & " " & B5 & " " & D5,
IF(A5 = "bar", A5 & " " & B5 & " " & C5,
IF(A5 = "foo", A5 & " " & B5,
"No If Formula Here yet")))
I started the formula off with the first two formatting's for you.